mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
4eb3db9a2c
After removal of auto-creating S we must ensure that all recipes are using a proper value for S. Fix all recipes that only need to set S equals to WORKDIR. [YOCTO #5627] (From OE-Core rev: 9d220b1bfe4589736604dd5a7129e3699377d830) Signed-off-by: Petter Mabäcker <petter@technux.se> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.2 KiB
BlitzBasic
45 lines
1.2 KiB
BlitzBasic
SUMMARY = "Runs postinstall scripts on first boot of the target device"
|
|
SECTION = "devel"
|
|
PR = "r9"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=4d92cd373abda3937c2bc47fbc49d690 \
|
|
file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
|
|
|
SRC_URI = "file://run-postinsts \
|
|
file://run-postinsts.init \
|
|
file://run-postinsts.service"
|
|
|
|
S = "${WORKDIR}"
|
|
|
|
inherit allarch systemd update-rc.d
|
|
|
|
INITSCRIPT_NAME = "run-postinsts"
|
|
INITSCRIPT_PARAMS = "start 99 S ."
|
|
|
|
SYSTEMD_SERVICE_${PN} = "run-postinsts.service"
|
|
|
|
do_configure() {
|
|
:
|
|
}
|
|
|
|
do_compile () {
|
|
:
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir}
|
|
install -m 0755 ${WORKDIR}/run-postinsts ${D}${sbindir}/
|
|
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${WORKDIR}/run-postinsts.init ${D}${sysconfdir}/init.d/run-postinsts
|
|
|
|
install -d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${WORKDIR}/run-postinsts.service ${D}${systemd_unitdir}/system/
|
|
|
|
sed -i -e 's:#SYSCONFDIR#:${sysconfdir}:g' \
|
|
-e 's:#SBINDIR#:${sbindir}:g' \
|
|
-e 's:#BASE_BINDIR#:${base_bindir}:g' \
|
|
${D}${sbindir}/run-postinsts \
|
|
${D}${systemd_unitdir}/system/run-postinsts.service
|
|
}
|