mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
0f25ab3481
flit_core can bootstrap itself, so the python3-flit-core recipe can just
inherit flit_core and set PEP517_SOURCE_PATH to the flit_core submodule.
Also setting FILES:${PN} is redundant.
(From OE-Core rev: ec8799eb92174cb6780a0cc7e1fa9828e4d75c79)
Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
36 lines
1.1 KiB
BlitzBasic
36 lines
1.1 KiB
BlitzBasic
SUMMARY = "This provides a PEP 517 build backend for packages using Flit."
|
|
DESCRIPTION = "This provides a PEP 517 build backend for packages using \
|
|
Flit. The only public interface is the API specified by PEP 517, at \
|
|
flit_core.buildapi."
|
|
HOMEPAGE = "https://github.com/pypa/flit"
|
|
BUGTRACKER = "https://github.com/pypa/flit/issues"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=41eb78fa8a872983a882c694a8305f08"
|
|
|
|
SRC_URI[sha256sum] = "3c9bd9c140515bfe62dd938c6610d10d6efb9e35cc647fc614fe5fb3a5036682"
|
|
|
|
inherit pypi flit_core
|
|
|
|
# Need to install by hand as there's a dependency loop
|
|
DEPENDS:remove:class-native = " python3-pip-native"
|
|
DEPENDS:append:class-native = " unzip-native"
|
|
|
|
# We need the full flit tarball
|
|
PYPI_PACKAGE = "flit"
|
|
PEP517_SOURCE_PATH = "${S}/flit_core"
|
|
PIP_INSTALL_PACKAGE = "flit_core"
|
|
|
|
do_install:class-native () {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
unzip -d ${D}${PYTHON_SITEPACKAGES_DIR} ${PIP_INSTALL_DIST_PATH}/flit_core*.whl
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES:${PN}-tests += "\
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core/tests/* \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|