mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 02:03:04 +01:00
fe80568a88
u-boot should be a non multilib recipe, add it in NON_MULTILIB_RECIPES. (From OE-Core rev: 5e7dc0d68efb2d43bbd5b1be9e6d555fc4456fb6) Signed-off-by: Ming Liu <liu.ming50@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
34 lines
1.4 KiB
Plaintext
34 lines
1.4 KiB
Plaintext
|
|
baselib = "${@d.getVar('BASE_LIB_tune-' + (d.getVar('DEFAULTTUNE') or 'INVALID')) or d.getVar('BASELIB')}"
|
|
|
|
MULTILIB_VARIANTS = "${@extend_variants(d,'MULTILIBS','multilib')}"
|
|
MULTILIB_SAVE_VARNAME = "DEFAULTTUNE TARGET_ARCH TARGET_SYS TARGET_VENDOR"
|
|
|
|
MULTILIBS ??= "multilib:lib32"
|
|
|
|
STAGING_DIR_HOST = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
STAGING_DIR_TARGET = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
RECIPE_SYSROOT = "${WORKDIR}/${MLPREFIX}recipe-sysroot"
|
|
RECIPE_SYSROOT_class-native = "${WORKDIR}/recipe-sysroot"
|
|
|
|
INHERIT += "multilib_global"
|
|
|
|
BBCLASSEXTEND_append = " ${MULTILIBS}"
|
|
|
|
MULTILIB_GLOBAL_VARIANTS ?= "lib32 lib64 libx32"
|
|
|
|
OPKG_ARGS_append = " --force-maintainer --force-overwrite"
|
|
|
|
# When multilib is enabled, allarch recipes will be installed into the MACHINE
|
|
# sysroot, not MLPREFIXMACHINE. This means that anything using pkg-config to
|
|
# find an allarch pkgconfig file will fail as the PKG_CONFIG_PATH only looks
|
|
# inside the multilib sysroot. Fix this by explicitly adding the MACHINE's
|
|
# architecture-independent pkgconfig location to PKG_CONFIG_PATH.
|
|
PKG_CONFIG_PATH .= ":${WORKDIR}/recipe-sysroot/${datadir}/pkgconfig"
|
|
PKG_CONFIG_PATH[vardepsexclude] = "datadir WORKDIR"
|
|
PKG_CONFIG_PATH[vardepvalueexclude] = ":${WORKDIR}/recipe-sysroot/${datadir}/pkgconfig"
|
|
|
|
# These recipes don't need multilib variants, the ${BPN} PROVDES/RPROVDES
|
|
# ${MLPREFIX}${BPN}
|
|
NON_MULTILIB_RECIPES = "grub grub-efi make-mod-scripts ovmf u-boot"
|