mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 01:06:37 +01:00
448dadd32c
(From OE-Core rev: bae1603a27fadcfa7257801167f28db3ff02dc97) Signed-off-by: Jacob Kroon <jacob.kroon@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.4 KiB
BlitzBasic
43 lines
1.4 KiB
BlitzBasic
# Note, we can probably remove the lzma option as it has be replaced with xz,
|
|
# and I don't think the kernel supports it any more.
|
|
SUMMARY = "Tools for manipulating SquashFS filesystems"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2"
|
|
LIC_FILES_CHKSUM = "file://../COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
PV = "4.4"
|
|
SRCREV = "52eb4c279cd283ed9802dd1ceb686560b22ffb67"
|
|
SRC_URI = "git://github.com/plougher/squashfs-tools.git;protocol=https \
|
|
file://0001-squashfs-tools-fix-build-failure-against-gcc-10.patch;striplevel=2 \
|
|
"
|
|
|
|
S = "${WORKDIR}/git/squashfs-tools"
|
|
|
|
EXTRA_OEMAKE = "${PACKAGECONFIG_CONFARGS}"
|
|
|
|
PACKAGECONFIG ??= "gzip xz lzo lz4 lzma xattr reproducible"
|
|
PACKAGECONFIG[gzip] = "GZIP_SUPPORT=1,GZIP_SUPPORT=0,zlib"
|
|
PACKAGECONFIG[xz] = "XZ_SUPPORT=1,XZ_SUPPORT=0,xz"
|
|
PACKAGECONFIG[lzo] = "LZO_SUPPORT=1,LZO_SUPPORT=0,lzo"
|
|
PACKAGECONFIG[lz4] = "LZ4_SUPPORT=1,LZ4_SUPPORT=0,lz4"
|
|
PACKAGECONFIG[lzma] = "LZMA_XZ_SUPPORT=1,LZMA_XZ_SUPPORT=0,xz"
|
|
PACKAGECONFIG[xattr] = "XATTR_SUPPORT=1,XATTR_SUPPORT=0,attr"
|
|
PACKAGECONFIG[zstd] = "ZSTD_SUPPORT=1,ZSTD_SUPPORT=0,zstd"
|
|
PACKAGECONFIG[reproducible] = "REPRODUCIBLE_DEFAULT=1,REPRODUCIBLE_DEFAULT=0,"
|
|
|
|
do_compile() {
|
|
oe_runmake all
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install INSTALL_DIR=${D}${sbindir}
|
|
}
|
|
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
ARM_INSTRUCTION_SET_armv6 = "arm"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
CVE_PRODUCT = "squashfs"
|