mirror of
https://git.yoctoproject.org/poky
synced 2026-02-13 12:13:02 +01:00
90288f32db
refresh pkgconfig.patch (From OE-Core rev: 0de14edfd16dc25d8a0dc0da120cda955dcc7576) Signed-off-by: Zheng Ruoqin <zhengrq.fnst@cn.fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.4 KiB
BlitzBasic
41 lines
1.4 KiB
BlitzBasic
SUMMARY = "Small library that defines common error values for all GnuPG components"
|
|
HOMEPAGE = "http://www.gnupg.org/related_software/libgpg-error/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
|
|
LICENSE = "GPLv2+ & LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
|
|
file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
file://src/gpg-error.h.in;beginline=2;endline=18;md5=d82591bc81561f617da71e00ff4a9d79 \
|
|
file://src/init.c;beginline=2;endline=17;md5=f01cdfcf747af5380590cfd9bbfeaaf7 \
|
|
"
|
|
|
|
|
|
SECTION = "libs"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libgpg-error/libgpg-error-${PV}.tar.bz2 \
|
|
file://pkgconfig.patch \
|
|
file://0001-Do-not-fail-when-testing-config-scripts.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "64b078b45ac3c3003d7e352a5e05318880a5778c42331ce1ef33d1a0d9922742"
|
|
|
|
BINCONFIG = "${bindir}/gpg-error-config"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig gettext multilib_header multilib_script
|
|
|
|
MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/gpgrt-config"
|
|
|
|
CPPFLAGS += "-P"
|
|
|
|
do_install_append() {
|
|
# we don't have common lisp in OE
|
|
rm -rf "${D}${datadir}/common-lisp/"
|
|
oe_multilib_header gpg-error.h gpgrt.h
|
|
}
|
|
|
|
FILES_${PN}-dev += "${bindir}/gpg-error"
|
|
FILES_${PN}-doc += "${datadir}/libgpg-error/errorref.txt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|