mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
f528d9878a
License-Update:
- COPYING:
* year updated
* the following files added:
fontconfig/fc-case/CaseFolding.txt
fontconfig/src/fcatomic.h
fontconfig/src/fcfoundry.h
fontconfig/src/fcmd5.h
fontconfig/src/fcmutex.h
fontconfig/src/ftglue.[ch]
- fcfreetype.c
* description of Copyright removed
* include files added
- fccache.c
* description of Copyright removed
* source code changed
(From OE-Core rev: 46f672e952d0670812983fd002ba989c13f93b01)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
2.7 KiB
BlitzBasic
71 lines
2.7 KiB
BlitzBasic
SUMMARY = "Generic font configuration library"
|
|
DESCRIPTION = "Fontconfig is a font configuration and customization library, which \
|
|
does not depend on the X Window System. It is designed to locate \
|
|
fonts within the system and select them according to requirements \
|
|
specified by applications. \
|
|
Fontconfig is not a rasterization library, nor does it impose a \
|
|
particular rasterization library on the application. The X-specific \
|
|
library 'Xft' uses fontconfig along with freetype to specify and \
|
|
rasterize fonts."
|
|
|
|
HOMEPAGE = "http://www.fontconfig.org"
|
|
BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=fontconfig"
|
|
|
|
LICENSE = "MIT & MIT & PD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=00252fd272bf2e722925613ad74cb6c7 \
|
|
file://src/fcfreetype.c;endline=45;md5=ce976b310a013a6ace6b60afa71851c1 \
|
|
file://src/fccache.c;beginline=1671;endline=1686;md5=906c2f04b0c79a1bcc84ecfca4de5619 \
|
|
"
|
|
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "expat freetype zlib gperf-native util-linux"
|
|
|
|
SRC_URI = "http://fontconfig.org/release/fontconfig-${PV}.tar.gz \
|
|
file://revert-static-pkgconfig.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "b8f607d556e8257da2f3616b4d704be30fd73bd71e367355ca78963f9a7f0434"
|
|
|
|
UPSTREAM_CHECK_REGEX = "fontconfig-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
|
|
|
|
do_configure:prepend() {
|
|
# work around https://bugs.freedesktop.org/show_bug.cgi?id=101280
|
|
rm -f ${S}/src/fcobjshash.h ${S}/src/fcobjshash.gperf
|
|
}
|
|
|
|
do_install:append:class-target() {
|
|
# duplicate fc-cache for postinstall script
|
|
mkdir -p ${D}${libexecdir}
|
|
ln ${D}${bindir}/fc-cache ${D}${libexecdir}/${MLPREFIX}fc-cache
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
# duplicate fc-cache for postinstall script
|
|
mkdir -p ${D}${libexecdir}
|
|
ln ${D}${bindir}/fc-cache ${D}${libexecdir}/${MLPREFIX}fc-cache
|
|
}
|
|
|
|
PACKAGES =+ "fontconfig-utils"
|
|
FILES:${PN} =+ "${datadir}/xml/*"
|
|
FILES:${PN}-dev += "${datadir}/gettext/*"
|
|
FILES:fontconfig-utils = "${bindir}/* ${libexecdir}/*"
|
|
|
|
# Work around past breakage in debian.bbclass
|
|
RPROVIDES:fontconfig-utils = "libfontconfig-utils"
|
|
RREPLACES:fontconfig-utils = "libfontconfig-utils"
|
|
RCONFLICTS:fontconfig-utils = "libfontconfig-utils"
|
|
DEBIAN_NOAUTONAME:fontconfig-utils = "1"
|
|
|
|
inherit autotools pkgconfig relative_symlinks gettext
|
|
|
|
FONTCONFIG_CACHE_DIR ?= "${localstatedir}/cache/fontconfig"
|
|
|
|
# comma separated list of additional directories
|
|
# /usr/share/fonts is already included by default (you can change it with --with-default-fonts)
|
|
FONTCONFIG_FONT_DIRS ?= "no"
|
|
|
|
EXTRA_OECONF = " --disable-docs --with-default-fonts=${datadir}/fonts --with-cache-dir=${FONTCONFIG_CACHE_DIR} --with-add-fonts=${FONTCONFIG_FONT_DIRS}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|