mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 18:53:13 +01:00
5337c1a3e3
Changelog: ========== * Fix compile with Meson on Solaris by defining __EXTENSIONS__. * Add support for the PKG_CONFIG_RELOCATE_PATHS environmental variable. When set, the program will act as if --define-prefix is always enabled. * Color solution nodes that were part of the original query, and use that coloring to skip over dependencies when generating DocumentNames in bomtool. * Enhance --env option to support variables with both --variable=varname and --print-variables. * Add --exists-cflags option which creates synthetic preprocessor definition flags for every queried dependency when found. * Document that Requires.private is always used for header paths. * Fix minor documentation typos. * Ensure string comparisons using <ctype.h> functions are done with unsigned bytes to avoid undefined behavior. * Fix parsing edge-case bugs with dependency versions. * Change PKG_PROG_PKG_CONFIG autoconf macro to add a customizable failure handler if pkg-config is not found. (From OE-Core rev: 7c2bc70bd62d05b0d39759a3b67f2f61ad6851c0) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.8 KiB
BlitzBasic
68 lines
2.8 KiB
BlitzBasic
SUMMARY = "pkgconf provides compiler and linker configuration for development frameworks."
|
|
DESCRIPTION = "pkgconf is a program which helps to configure compiler and linker \
|
|
flags for development frameworks. It is similar to pkg-config from \
|
|
freedesktop.org, providing additional functionality while also maintaining \
|
|
compatibility."
|
|
HOMEPAGE = "http://pkgconf.org"
|
|
BUGTRACKER = "https://github.com/pkgconf/pkgconf/issues"
|
|
SECTION = "devel"
|
|
PROVIDES += "pkgconfig"
|
|
RPROVIDES:${PN} += "pkgconfig"
|
|
|
|
# The pkgconf license seems to be functionally equivalent to BSD-2-Clause or
|
|
# ISC, but has different wording, so needs its own name.
|
|
LICENSE = "pkgconf"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2214222ec1a820bd6cc75167a56925e0"
|
|
|
|
SRC_URI = "\
|
|
https://distfiles.ariadne.space/pkgconf/pkgconf-${PV}.tar.xz \
|
|
file://pkg-config-wrapper \
|
|
file://pkg-config-native.in \
|
|
file://pkg-config-esdk.in \
|
|
"
|
|
SRC_URI[sha256sum] = "3a9080ac51d03615e7c1910a0a2a8df08424892b5f13b0628a204d3fcce0ea8b"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF += "--with-pkg-config-dir='${libdir}/pkgconfig:${datadir}/pkgconfig'"
|
|
|
|
do_install:append () {
|
|
# Install a wrapper which deals, as much as possible with pkgconf vs
|
|
# pkg-config compatibility issues.
|
|
install -m 0755 "${UNPACKDIR}/pkg-config-wrapper" "${D}${bindir}/pkg-config"
|
|
}
|
|
|
|
do_install:append:class-native () {
|
|
# Install a pkg-config-native wrapper that will use the native sysroot instead
|
|
# of the MACHINE sysroot, for using pkg-config when building native tools.
|
|
sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \
|
|
< ${UNPACKDIR}/pkg-config-native.in > ${B}/pkg-config-native
|
|
install -m755 ${B}/pkg-config-native ${D}${bindir}/pkg-config-native
|
|
sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \
|
|
-e "s|@LIBDIR_NATIVE@|${PKG_CONFIG_LIBDIR}|" \
|
|
< ${UNPACKDIR}/pkg-config-esdk.in > ${B}/pkg-config-esdk
|
|
install -m755 ${B}/pkg-config-esdk ${D}${bindir}/pkg-config-esdk
|
|
}
|
|
|
|
# When using the RPM generated automatic package dependencies, some packages
|
|
# will end up requiring 'pkgconfig(pkg-config)'. Allow this behavior by
|
|
# specifying an appropriate provide.
|
|
RPROVIDES:${PN} += "pkgconfig(pkg-config)"
|
|
|
|
# Include pkg.m4 in the main package, leaving libpkgconf dev files in -dev
|
|
FILES:${PN}-dev:remove = "${datadir}/aclocal"
|
|
FILES:${PN} += "${datadir}/aclocal"
|
|
|
|
BBCLASSEXTEND += "native nativesdk"
|
|
|
|
pkgconf_sstate_fixup_esdk () {
|
|
if [ "${BB_CURRENTTASK}" = "populate_sysroot_setscene" -a "${WITHIN_EXT_SDK}" = "1" ] ; then
|
|
pkgconfdir="${SSTATE_INSTDIR}/recipe-sysroot-native/${bindir_native}"
|
|
mv $pkgconfdir/pkg-config $pkgconfdir/pkg-config.real
|
|
ln -rs $pkgconfdir/pkg-config-esdk $pkgconfdir/pkg-config
|
|
sed -i -e "s|^pkg-config|pkg-config.real|" $pkgconfdir/pkg-config-native
|
|
fi
|
|
}
|
|
|
|
SSTATEPOSTUNPACKFUNCS:append:class-native = " pkgconf_sstate_fixup_esdk"
|