mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 11:13:04 +01:00
dfa34c27bd
Move the CONFIGURE_FILES assignment from python_mesonpy to the common class, as it isn't specific to mesonpy. Also extend, so that it doesn't clobber existing settings. (From OE-Core rev: 049cd6b62853c020b0c85ccee18638ec58887866) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.1 KiB
Plaintext
47 lines
1.1 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
inherit meson setuptools3-base python3targetconfig python_pep517
|
|
|
|
# meson_do_qa_configure does the wrong thing here because
|
|
# mesonpy runs "meson setup ..." in do_compile context.
|
|
# Make it a dummy function.
|
|
meson_do_qa_configure () {
|
|
:
|
|
}
|
|
|
|
# This prevents the meson error:
|
|
# ERROR: Got argument buildtype as both -Dbuildtype and --buildtype. Pick one.
|
|
MESONOPTS:remove = "--buildtype ${MESON_BUILDTYPE}"
|
|
|
|
DEPENDS += "python3-wheel-native python3-meson-python-native"
|
|
|
|
def mesonpy_get_args(d):
|
|
vars = ['MESONOPTS', 'MESON_CROSS_FILE', 'EXTRA_OEMESON']
|
|
varlist = []
|
|
for var in vars:
|
|
value = d.getVar(var)
|
|
vallist = value.split()
|
|
for elem in vallist:
|
|
varlist.append("-Csetup-args=" + elem)
|
|
return ' '.join(varlist)
|
|
|
|
PEP517_BUILD_OPTS = "-Cbuilddir='${B}' ${@mesonpy_get_args(d)}"
|
|
|
|
python_mesonpy_do_configure () {
|
|
python_pep517_do_configure
|
|
}
|
|
|
|
python_mesonpy_do_compile () {
|
|
python_pep517_do_compile
|
|
}
|
|
|
|
python_mesonpy_do_install () {
|
|
python_pep517_do_install
|
|
}
|
|
|
|
EXPORT_FUNCTIONS do_configure do_compile do_install
|