mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 18:32:13 +02:00
58396952e3
https://github.com/KhronosGroup/Vulkan-Loader/compare/vulkan-sdk-1.3.280.0...vulkan-sdk-1.3.283 [RP: fix branch] (From OE-Core rev: c5af929b0f6df24b3dde1ee9159e0ab630727173) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.8 KiB
BlitzBasic
44 lines
1.8 KiB
BlitzBasic
SUMMARY = "3D graphics and compute API common loader"
|
|
DESCRIPTION = "Vulkan is a new generation graphics and compute API \
|
|
that provides efficient access to modern GPUs. These packages \
|
|
provide only the common vendor-agnostic library loader, headers and \
|
|
the vulkaninfo utility."
|
|
HOMEPAGE = "https://www.khronos.org/vulkan/"
|
|
BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-Loader"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=7dbefed23242760aa3475ee42801c5ac"
|
|
SRC_URI = "git://github.com/KhronosGroup/Vulkan-Loader.git;branch=vulkan-sdk-1.3.283;protocol=https"
|
|
SRCREV = "720be5198aad4696381d2e3eeadc131c9f56bdc6"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
REQUIRED_DISTRO_FEATURES = "vulkan"
|
|
|
|
inherit cmake features_check pkgconfig
|
|
|
|
DEPENDS += "vulkan-headers"
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_TESTS=OFF \
|
|
-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
|
|
-DASSEMBLER_WORKS=FALSE \
|
|
-DVulkanHeaders_INCLUDE_DIR=${STAGING_INCDIR} \
|
|
-DVulkanRegistry_DIR=${RECIPE_SYSROOT}/${datadir} \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
|
|
PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
|
|
|
|
RRECOMMENDS:${PN} = "mesa-vulkan-drivers"
|
|
|
|
# These recipes need to be updated in lockstep with each other:
|
|
# glslang, vulkan-headers, vulkan-loader, vulkan-tools, spirv-headers, spirv-tools,
|
|
# vulkan-validation-layers, vulkan-utility-libraries, vulkan-volk.
|
|
# The tags versions should always be sdk-x.y.z, as this is what
|
|
# upstream considers a release.
|
|
UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
|