mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 15:32:12 +02:00
86a22e0d5d
fix below errors which caused by race condition: do_package: ERROR: dwarfsrcfiles failed with exit code 1 (cmd was ['dwarfsrcfiles', 'TOPDIR/tmp-glibc/work/ppc7400-oe-linux/sysklogd/2.1.2-r0/package/usr/lib/libsyslog.a']): dwarfsrcfiles: TOPDIR/tmp-glibc/work/ppc7400-oe-linux/sysklogd/2.1.2-r0/package/usr/lib/libsyslog.a: not a valid ELF file do_compile: arm-oe-linux-gnueabi-libtool: link: (cd ".libs" && rm -f "libsyslog.so.0" && ln -s "libsyslog.so.0.0.0" "libsyslog.so.0") arm-oe-linux-gnueabi-libtool: link: (cd ".libs" && rm -f "libsyslog.so" && ln -s "libsyslog.so.0.0.0" "libsyslog.so") arm-oe-linux-gnueabi-libtool: link: arm-oe-linux-gnueabi-gcc-ar cru .libs/libsyslog.a libsyslog_la-syslog.o ../lib/pidfile.o ../lib/strlcpy.o ../lib/strlcat.o TOPDIR/tmp-glibc/work/armv7vet2hf-neon-oe-linux-gnueabi/sysklogd/2.1.2-r0/recipe-sysroot-native/usr/bin/arm-oe-linux-gnueabi/../../libexec/arm-oe-linux-gnueabi/gcc/arm-oe-linux-gnueabi/10.1.0/ar: `u' modifier ignored since `D' is the default (see `U') TOPDIR/tmp-glibc/work/armv7vet2hf-neon-oe-linux-gnueabi/sysklogd/2.1.2-r0/recipe-sysroot-native/usr/bin/arm-oe-linux-gnueabi/../../libexec/arm-oe-linux-gnueabi/gcc/arm-oe-linux-gnueabi/10.1.0/ar: ../lib/strlcat.o: No such file or directory (From OE-Core rev: 3bab002a3fe4f15529a4771fb982f921a77eedfe) Signed-off-by: Changqing Li <changqing.li@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.7 KiB
PHP
55 lines
1.7 KiB
PHP
SUMMARY = "System Log Daemons"
|
|
DESCRIPTION = "The sysklogd package implements system log daemons: syslogd"
|
|
HOMEPAGE = "http://www.infodrom.org/projects/sysklogd/"
|
|
SECTION = "base"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5b4be4b2549338526758ef479c040943 \
|
|
file://src/syslogd.c;beginline=2;endline=15;md5=a880fecbc04503f071c494a9c0dd4f97 \
|
|
"
|
|
|
|
inherit update-rc.d update-alternatives systemd autotools
|
|
|
|
SRC_URI = "git://github.com/troglobit/sysklogd.git;nobranch=1 \
|
|
file://sysklogd \
|
|
file://0001-Makefile.am-fixup-issue-17.patch \
|
|
"
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF = "--with-systemd=${systemd_system_unitdir} --without-logger"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}
|
|
install -m 644 ${S}/syslog.conf ${D}${sysconfdir}/syslog.conf
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 755 ${WORKDIR}/sysklogd ${D}${sysconfdir}/init.d/syslog
|
|
}
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE_${PN} = "syslogd.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
INITSCRIPT_NAME = "syslog"
|
|
CONFFILES_${PN} = "${sysconfdir}/syslog.conf"
|
|
RCONFLICTS_${PN} = "rsyslog busybox-syslog syslog-ng"
|
|
|
|
FILES_${PN} += "${@bb.utils.contains('DISTRO_FEATURES','systemd','${exec_prefix}/lib/tmpfiles.d/sysklogd.conf', '', d)}"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE_${PN}-doc = "syslogd.8"
|
|
ALTERNATIVE_LINK_NAME[syslogd.8] = "${mandir}/man8/syslogd.8"
|
|
|
|
pkg_prerm_${PN} () {
|
|
if test "x$D" = "x"; then
|
|
if test "$1" = "upgrade" -o "$1" = "remove"; then
|
|
/etc/init.d/syslog stop || :
|
|
fi
|
|
fi
|
|
}
|
|
|
|
python () {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
|
|
}
|