mirror of
https://git.yoctoproject.org/poky
synced 2026-02-22 17:39:39 +01:00
44b0aa3426
The following commit was integrated into the 5.19.15 -stable series and breaks the elfutils backtrace ptests. don't use __kernel_write() on kmap_local_page() It could be that other commits are also required in -stable, but a revert is the easiest way to deal with the regression. We can revisit newer kernel's (where the commit is also present) if they also start to fail the test. (From OE-Core rev: e137ca045d21476394b12725447affe4c99b8e03) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
3.4 KiB
BlitzBasic
71 lines
3.4 KiB
BlitzBasic
KBRANCH ?= "v5.19/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v5.19/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v5.19/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v5.19/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v5.19/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v5.19/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v5.19/standard/base"
|
|
KBRANCH:qemux86 ?= "v5.19/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v5.19/standard/base"
|
|
KBRANCH:qemumips64 ?= "v5.19/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "dee954e39057710f00e5b3ea23514d01f3a4d940"
|
|
SRCREV_machine:qemuarm64 ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemumips ?= "fe2b95c83e022371019027da3dd068ab33576d3f"
|
|
SRCREV_machine:qemuppc ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemuriscv64 ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemuriscv32 ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemux86 ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemux86-64 ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_machine:qemumips64 ?= "a5f29b9c64f2b3b47f74fee38f298d8a6b17a8b3"
|
|
SRCREV_machine ?= "aaf4490d1807c49e3e0ceab1372533937ef2c82b"
|
|
SRCREV_meta ?= "0cba9aa40445bf59bfa651e1bd43a31c2ca7d524"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "2b525314c7b57eac29fe8b77a6589428e4a4f6dd"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v5.19/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.19;destsuffix=${KMETA}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "5.19.17"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|