mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
b0130fcf91
An automated conversion using scripts/contrib/convert-spdx-licenses.py to convert to use the standard SPDX license identifiers. Two recipes in meta-selftest were not converted as they're that way specifically for testing. A change in linux-firmware was also skipped and may need a more manual tweak. (From OE-Core rev: ceda3238cdbf1beb216ae9ddb242470d5dfc25e0) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.2 KiB
BlitzBasic
37 lines
1.2 KiB
BlitzBasic
SUMMARY = "Real-Time preemption testcases"
|
|
HOMEPAGE = "https://wiki.linuxfoundation.org/realtime/documentation/start"
|
|
DESCRIPTION = "The main aim of the PREEMPT_RT patch is to minimize the amount of kernel code that is non-preemptible Therefore several substitution mechanisms and new mechanisms are implemented."
|
|
SECTION = "tests"
|
|
DEPENDS = "linux-libc-headers virtual/libc numactl"
|
|
LICENSE = "GPL-2.0-only & GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
|
|
require rt-tests.inc
|
|
inherit ptest
|
|
|
|
SRC_URI += " \
|
|
file://run-ptest \
|
|
file://rt_bmark.py \
|
|
file://0001-Makefile-Allow-for-CC-and-AR-to-be-overridden.patch \
|
|
"
|
|
|
|
# rt-tests needs PI mutex support in libc
|
|
COMPATIBLE_HOST:libc-musl = 'null'
|
|
|
|
# Do not install hwlatdetect
|
|
EXTRA_OEMAKE += "PYLIB=''"
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} \
|
|
INCLUDEDIR=${includedir}
|
|
}
|
|
|
|
do_install_ptest() {
|
|
cp ${WORKDIR}/rt_bmark.py ${D}${PTEST_PATH}
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += " stress-ng python3 python3-multiprocessing python3-datetime python3-misc"
|
|
|
|
FILES:${PN} += "${prefix}/src/backfire"
|
|
RDEPENDS:${PN} += "bash"
|