mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 09:32:14 +02:00
cd007488d2
gettext installs a libtool .la file for non-glibc systems since it builds libintl for them unlike glibc where it finds that using libc's gettext implementation is just fine. Same is not true for musl even though musl provides itw own gettext implementation much on then lines of glibc. ideally gettetxt should be fixed to behave on musl, but at this time its not clear if APIs are same and complete. Deleting .la file helps compiling packages like util-linux when using fstack-protections since it does not alter the order of libc on linker cmdline Moved src_uri checksums just below the SRC_URI as matter of formatting (From OE-Core rev: 83d31c874c58c9e98f1f99cbad1a583e65ed72e6) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
116 lines
5.0 KiB
BlitzBasic
116 lines
5.0 KiB
BlitzBasic
SUMMARY = "Utilities and libraries for producing multi-lingual messages"
|
|
DESCRIPTION = "GNU gettext is a set of tools that provides a framework to help other programs produce multi-lingual messages. These tools include a set of conventions about how programs should be written to support message catalogs, a directory and file naming organization for the message catalogs themselves, a runtime library supporting the retrieval of translated messages, and a few stand-alone programs to massage in various ways the sets of translatable and already translated strings."
|
|
HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
|
|
SECTION = "libs"
|
|
LICENSE = "GPLv3+ & LGPL-2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS = "gettext-native virtual/libiconv expat"
|
|
DEPENDS_class-native = "gettext-minimal-native"
|
|
PROVIDES = "virtual/libintl virtual/gettext"
|
|
PROVIDES_class-native = "virtual/gettext-native"
|
|
RCONFLICTS_${PN} = "proxy-libintl"
|
|
SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
|
|
file://parallel.patch \
|
|
file://add-with-bisonlocaledir.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "6d1447f8c5c45c329371ef4bfe7d79a5"
|
|
SRC_URI[sha256sum] = "ed4b4c19bd3a3034eb6769500a3592ff616759ef43cf30586dbb7a17c9dd695d"
|
|
|
|
PACKAGECONFIG[msgcat-curses] = "--with-libncurses-prefix=${STAGING_LIBDIR}/..,--disable-curses,ncurses,"
|
|
|
|
LDFLAGS_prepend_libc-uclibc = " -lrt -lpthread "
|
|
|
|
inherit autotools texinfo
|
|
|
|
EXTRA_OECONF += "--without-lispdir \
|
|
--disable-csharp \
|
|
--disable-libasprintf \
|
|
--disable-java \
|
|
--disable-native-java \
|
|
--disable-openmp \
|
|
--disable-acl \
|
|
--with-included-glib \
|
|
--without-emacs \
|
|
--without-cvs \
|
|
--without-git \
|
|
--with-included-libxml \
|
|
--with-included-libcroco \
|
|
--with-included-libunistring \
|
|
"
|
|
EXTRA_OECONF_append_class-target = " \
|
|
--with-bisonlocaledir=${datadir}/locale \
|
|
"
|
|
|
|
acpaths = '-I ${S}/gettext-runtime/m4 \
|
|
-I ${S}/gettext-tools/m4'
|
|
|
|
do_install_append_libc-musl () {
|
|
rm -f ${D}${libdir}/charset.alias
|
|
rm -f ${D}${includedir}/libintl.h
|
|
rm -f ${D}${libdir}/libintl.la
|
|
}
|
|
|
|
# these lack the .x behind the .so, but shouldn't be in the -dev package
|
|
# Otherwise you get the following results:
|
|
# 7.4M glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
|
|
# 25M uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
|
|
# because gettext depends on gettext-dev, which pulls in more -dev packages:
|
|
# 15228 KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
|
|
# 1300 KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
|
|
# 140 KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
|
|
# 4 KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
|
|
|
|
PACKAGES =+ "libgettextlib libgettextsrc"
|
|
FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
|
|
FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
|
|
|
|
PACKAGES =+ "gettext-runtime gettext-runtime-dev gettext-runtime-doc"
|
|
|
|
FILES_${PN} += "${libdir}/${BPN}/*"
|
|
|
|
FILES_gettext-runtime = "${bindir}/gettext \
|
|
${bindir}/ngettext \
|
|
${bindir}/envsubst \
|
|
${bindir}/gettext.sh \
|
|
${libdir}/libasprintf.so* \
|
|
${libdir}/GNU.Gettext.dll \
|
|
"
|
|
FILES_gettext-runtime_append_libc-uclibc = " ${libdir}/libintl.so.* \
|
|
${libdir}/charset.alias \
|
|
"
|
|
FILES_gettext-runtime-dev += "${libdir}/libasprintf.a \
|
|
${includedir}/autosprintf.h \
|
|
"
|
|
FILES_gettext-runtime-dev_append_libc-uclibc = " ${libdir}/libintl.so \
|
|
${includedir}/libintl.h \
|
|
"
|
|
FILES_gettext-runtime-doc = "${mandir}/man1/gettext.* \
|
|
${mandir}/man1/ngettext.* \
|
|
${mandir}/man1/envsubst.* \
|
|
${mandir}/man1/.* \
|
|
${mandir}/man3/* \
|
|
${docdir}/gettext/gettext.* \
|
|
${docdir}/gettext/ngettext.* \
|
|
${docdir}/gettext/envsubst.* \
|
|
${docdir}/gettext/*.3.html \
|
|
${datadir}/gettext/ABOUT-NLS \
|
|
${docdir}/gettext/csharpdoc/* \
|
|
${docdir}/libasprintf/autosprintf.html \
|
|
${infodir}/autosprintf.info \
|
|
"
|
|
|
|
do_install_append() {
|
|
rm -f ${D}${libdir}/preloadable_libintl.so
|
|
}
|
|
|
|
do_install_append_class-native () {
|
|
rm ${D}${datadir}/aclocal/*
|
|
rm ${D}${datadir}/gettext/config.rpath
|
|
rm ${D}${datadir}/gettext/po/Makefile.in.in
|
|
rm ${D}${datadir}/gettext/po/remove-potcdate.sin
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|