mirror of
https://git.yoctoproject.org/poky
synced 2026-02-13 12:13:02 +01:00
b4cf3f305c
The LINUX_VERSION was previously updated to 4.1.32, but the SRCREVs for the actual content were missed. This gets our actual version and the PV back in sync. We also update the meta data to fix configuration audit warnings from the beaglebone builds. (From OE-Core rev: 255adfaddec0dc44db619bf8726cd7804c09400d) Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com> squash with 4.1 Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.4 KiB
BlitzBasic
37 lines
1.4 KiB
BlitzBasic
KBRANCH ?= "standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("PREFERRED_PROVIDER_virtual/kernel", True) != "linux-yocto-rt":
|
|
raise bb.parse.SkipPackage("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "91821a6c3a54fabf964037dd478944a8f3597f88"
|
|
SRCREV_meta ?= "19cafe114e7d35e6202afa1079b32ce600646660"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto-4.1.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-4.1;destsuffix=${KMETA}"
|
|
|
|
LINUX_VERSION ?= "4.1.32"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "2"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuppc|qemumips)"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc"
|