mirror of
https://git.yoctoproject.org/poky
synced 2026-03-03 13:59:40 +01:00
11d99fba1f
`googlemock` has been absorbed into the [googletest](https://github.com/google/googletest) project and is built and installed from the same source tree. `googletest` has provided a CMake Config-file Package starting with GTest 1.8.1. `find_package(GTest ...)` by default dispatches first to CMake Find Module. Starting with CMake commit 2327b4330cce157d616ff8b611b3e77568d00351 in CMake v3.20.0 the module dispatches onward to the Config-file Package so that the same targets are available. In pre v3.20.0 versions of CMake however the Find Module masks the targets provided by the upstream `GTest` package. Update `Modules/FindGTest.cmake` to provide the same targets as the CMake Config-file Package and backwards compatible targets and result variables. (From OE-Core rev: 3b05fb01ec0e51c85d8ed62618467e57be91b928) Signed-off-by: Eero Aaltonen <eero.aaltonen@vaisala.com> Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.7 KiB
BlitzBasic
54 lines
1.7 KiB
BlitzBasic
require cmake.inc
|
|
inherit native
|
|
|
|
DEPENDS += "bzip2-replacement-native expat-native xz-native zlib-native curl-native ncurses-native"
|
|
|
|
SRC_URI += "file://OEToolchainConfig.cmake \
|
|
file://environment.d-cmake.sh \
|
|
file://0001-CMakeDetermineSystem-use-oe-environment-vars-to-load.patch \
|
|
file://0005-Disable-use-of-ext2fs-ext2_fs.h-by-cmake-s-internal-.patch \
|
|
file://0006-cmake-FindGTest-Add-target-for-gmock-library.patch \
|
|
"
|
|
|
|
|
|
B = "${WORKDIR}/build"
|
|
do_configure[cleandirs] = "${B}"
|
|
|
|
CMAKE_EXTRACONF = "\
|
|
-DCMAKE_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE} \
|
|
-DBUILD_CursesDialog=1 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARIES=1 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBARCHIVE=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
|
|
-DCMAKE_USE_SYSTEM_LIBRARY_LIBRHASH=0 \
|
|
-DENABLE_ACL=0 -DHAVE_ACL_LIBACL_H=0 \
|
|
-DHAVE_SYS_ACL_H=0 \
|
|
"
|
|
|
|
do_configure () {
|
|
${S}/configure --verbose --prefix=${prefix} \
|
|
${@oe.utils.parallel_make_argument(d, '--parallel=%d')} \
|
|
${@bb.utils.contains('CCACHE', 'ccache ', '--enable-ccache', '', d)} \
|
|
-- ${CMAKE_EXTRACONF}
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
|
|
# The following codes are here because eSDK needs to provide compatibilty
|
|
# for SDK. That is, eSDK could also be used like traditional SDK.
|
|
mkdir -p ${D}${datadir}/cmake
|
|
install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/
|
|
mkdir -p ${D}${base_prefix}/environment-setup.d
|
|
install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${base_prefix}/environment-setup.d/cmake.sh
|
|
}
|
|
|
|
do_compile[progress] = "percent"
|
|
|
|
SYSROOT_DIRS_NATIVE += "${datadir}/cmake ${base_prefix}/environment-setup.d"
|