mirror of
https://git.yoctoproject.org/poky
synced 2026-03-05 14:59:41 +01:00
43cdee3282
Added HOMEPAGE and DESCRIPTION for recipes with missing decriptions or homepage [YOCTO #13471] (From OE-Core rev: bd3352880322598b0ba6dc439ff08c2e4c592e36) Signed-off-by: Dorinda Bassey <dorindabassey@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit bb05814335e7101bfd8df0a11dc18a044e867bed) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
32 lines
1.2 KiB
BlitzBasic
32 lines
1.2 KiB
BlitzBasic
SUMMARY = "Optimised Inner Loop Runtime Compiler"
|
|
HOMEPAGE = "http://gstreamer.freedesktop.org/modules/orc.html"
|
|
DESCRIPTION = "Optimised Inner Loop Runtime Compiler is a Library and set of tools for compiling and executing SIMD assembly language-like programs that operate on arrays of data."
|
|
LICENSE = "BSD-2-Clause & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1400bd9d09e8af56b9ec982b3d85797e"
|
|
|
|
SRC_URI = "http://gstreamer.freedesktop.org/src/orc/orc-${PV}.tar.xz"
|
|
SRC_URI[md5sum] = "b6b95a47eff713e91873e2c2b1a5b3ad"
|
|
SRC_URI[sha256sum] = "a0ab5f10a6a9ae7c3a6b4218246564c3bf00d657cbdf587e6d34ec3ef0616075"
|
|
|
|
inherit meson pkgconfig gtk-doc
|
|
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
GTKDOC_MESON_ENABLE_FLAG = "enabled"
|
|
GTKDOC_MESON_DISABLE_FLAG = "disabled"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
PACKAGES =+ "orc-examples"
|
|
PACKAGES_DYNAMIC += "^liborc-.*"
|
|
FILES_orc-examples = "${libdir}/orc/*"
|
|
FILES_${PN} = "${bindir}/*"
|
|
|
|
python populate_packages_prepend () {
|
|
libdir = d.expand('${libdir}')
|
|
do_split_packages(d, libdir, r'^lib(.*)\.so\.*', 'lib%s', 'ORC %s library', extra_depends='', allow_links=True)
|
|
}
|
|
|
|
do_compile_prepend_class-native () {
|
|
sed -i -e 's#/tmp#.#g' ${S}/orc/orccodemem.c
|
|
}
|