mirror of
https://git.yoctoproject.org/poky
synced 2026-03-12 02:09:39 +01:00
72f4f94d4e
Latest stable branch update Drop 0029-network-enable-KeepConfiguration-when-running-on-net.patch as patch merged upstream. Changes: 4a31fa2fb0 (tag: v250.5) hwdb: run "update-hwdb-autosuspend" e92e2d0e3b hwdb: run "update-hwdb" e1e4395775 hwdb: make sure "ninja update-hwdb" works on f35 1fe496fc3b hwdb: fix parser to work with newer pyparsing 32e7c65372 manager: prohibit clone3() in seccomp filters 45335a3eed nspawn: fix --ephemeral with --machine 79b86adcbd nspawn: fix locating config files with --ephemeral c202d402d9 resolve: fix typo in dns_class_is_pseudo() 9f689fda54 sd-ipv4acd: actually drop the arp packet from one of the host interface e3d57bc301 sd-event: make inotify event work after the process is forked a5fc32fa34 sd-event: do not kill a child process from another child c36ab05b4f sd-event: do not update signal fd after PID is changed e006b56c18 sd-event: set pid to event source after all setup processes finished d2e3b5a841 sd-event: rebreak comments 6673131917 core: fix dm-verity auto-discovery in MountImageUnit() 10ee46a2ca analyze: Fix verify exit status regression df6253cbda hwdb: fix parsing options 9727b9ee7b core: command argument can be longer than PATH_MAX 12f05b856c network: ignore all errors in loading .network files b5dfdf0301 analyze: fix offline check for syscal filter 8ed1490de6 analyze: fix offline check for 'native' syscall architecture 72d0c6b171 missing-syscall: define MOVE_MOUNT_T_EMPTY_PATH if missing bba396d78c journal-remote: refuse to specify --trust option when gnutls is disabled 8d4c0d2383 calendarspec: fix possibly skips next elapse d9ea8dab6d copy: use FLAGS_SET() in copy_xattr() 077ca08b38 journal: preserve acls when rotating user journals with NOCOW attribute set 25b3c48ec5 macro: account for negative values in DECIMAL_STR_WIDTH() 8f2f6a94d8 network: enable KeepConfiguration= when running on network filesystem 61649fbada stat-util: introduce path_is_network_fs() 3f6e62eccb network-generator: rename DHCP_TYPE_DHCP -> DHCP_TYPE_DHCP4 a7585a3a38 hwdb: Add AV production access to Elgado Stream Deck devices 18c0096ec2 Add AV production controllers to hwdb and add uaccess 2298094b2c packit: drop bfq patch 7cda67d4f4 packit: build on and use Fedora 36 spec file 056bae9f1b Packit: build SRPMs in Copr 6253eb576c journal-file: if we are going down, don't use event loop to schedule post c901bc8680 journald: make sure SIGTERM handling doesn't get starved out ed46ff2bd6 random-seed: hash together old seed and new seed before writing out file 6d3e2f0188 resolved: Allow test-resolved-stream to run concurrently 781b2b2e66 resolved: Read as much as possible per stream EPOLLIN event 03692af607 resolved: Avoid multiple SSL writes per DoT packet 3227f542a7 resolved: Make event flags logic robust for DoT 9c710c66c3 resolve: llmnr: fix never hit condition d65808ef7e resolve: mention that dns_stream_update() needs to be called after dns_stream_take_read_packet() b2f82f643a resolve: call dns_stream_take_read_packet() in on_stream_io() fe4c208c98 resolve: make dns_stream_new() take on_packet and complete callbacks f447648ae4 resolved: Test for DnsStream (plain TCP DNS and DoT) 88b4e8f74e resolved: Fix DoT timeout on multiple answer records d5b871bdfe test: increase image size c3aead5568 random-util: unify RANDOM_ALLOW_INSECURE and !RANDOM_BLOCK and simplify (From OE-Core rev: 43e2cd211230ea32e4903f9891fda2e4b0f63cc4) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit e07ba76fc78b44f338e574644a8ae3b6cddc9f08) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
74 lines
2.1 KiB
BlitzBasic
74 lines
2.1 KiB
BlitzBasic
require systemd.inc
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemd:"
|
|
|
|
require conf/image-uefi.conf
|
|
|
|
DEPENDS = "intltool-native libcap util-linux gnu-efi gperf-native python3-jinja2-native"
|
|
|
|
inherit meson pkgconfig gettext
|
|
inherit deploy
|
|
|
|
LDFLAGS:prepend = "${@ " ".join(d.getVar('LD').split()[1:])} "
|
|
|
|
do_write_config[vardeps] += "CC OBJCOPY"
|
|
do_write_config:append() {
|
|
cat >${WORKDIR}/meson-${PN}.cross <<EOF
|
|
[binaries]
|
|
efi_cc = ${@meson_array('CC', d)}
|
|
objcopy = ${@meson_array('OBJCOPY', d)}
|
|
EOF
|
|
}
|
|
|
|
EFI_LD = "bfd"
|
|
|
|
EXTRA_OEMESON += "-Defi=true \
|
|
-Dgnu-efi=true \
|
|
-Defi-includedir=${STAGING_INCDIR}/efi \
|
|
-Defi-libdir=${STAGING_LIBDIR} \
|
|
-Defi-ld=${EFI_LD} \
|
|
-Dman=false \
|
|
--cross-file ${WORKDIR}/meson-${PN}.cross \
|
|
"
|
|
|
|
# install to the image as boot*.efi if its the EFI_PROVIDER,
|
|
# otherwise install as the full name.
|
|
# This allows multiple bootloaders to coexist in a single image.
|
|
python __anonymous () {
|
|
import re
|
|
target = d.getVar('TARGET_ARCH')
|
|
prefix = "" if d.getVar('EFI_PROVIDER') == "systemd-boot" else "systemd-"
|
|
systemdimage = prefix + d.getVar("EFI_BOOT_IMAGE")
|
|
d.setVar("SYSTEMD_BOOT_IMAGE", systemdimage)
|
|
prefix = "systemd-" if prefix == "" else ""
|
|
d.setVar("SYSTEMD_BOOT_IMAGE_PREFIX", prefix)
|
|
}
|
|
|
|
FILES:${PN} = "${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}"
|
|
|
|
RDEPENDS:${PN} += "virtual-systemd-bootconf"
|
|
|
|
# Imported from the old gummiboot recipe
|
|
TUNE_CCARGS:remove = "-mfpmath=sse"
|
|
|
|
COMPATIBLE_HOST = "(aarch64.*|arm.*|x86_64.*|i.86.*)-linux"
|
|
COMPATIBLE_HOST:x86-x32 = "null"
|
|
|
|
do_compile() {
|
|
ninja \
|
|
src/boot/efi/${SYSTEMD_BOOT_IMAGE_PREFIX}${SYSTEMD_BOOT_IMAGE} \
|
|
src/boot/efi/linux${EFI_ARCH}.efi.stub
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${EFI_FILES_PATH}
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${D}${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}
|
|
}
|
|
|
|
do_deploy () {
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${DEPLOYDIR}
|
|
install ${B}/src/boot/efi/linux*.efi.stub ${DEPLOYDIR}
|
|
}
|
|
|
|
addtask deploy before do_build after do_compile
|
|
|