mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
cfbf6fad48
The eglibc core build still has a number of issues with /bin/dash.
Recently found is both sysdeps/unix/make-syscalls.sh and it's output,
which make calls via SHELL do not play well with /bin/dash. By force
make to use /bin/bash via SHELL setting it works correctly.
Currenly known issues are: make-syscalls.sh line with a bad substitution,
which can be corrected by:
vdso_symver="$(printf '%s\n' ${vdso_symver} | sed 's/\./_/')"
Following that there is an issue with emiting a '\n' through a second
echo and then to the compiler. There maybe more issues beyond that.
[YOCTO #3080]
(From OE-Core rev: 9d002f7cdc5309c4d850a76e4fd73ff04c980a07)
Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.9 KiB
PHP
72 lines
2.9 KiB
PHP
require eglibc-common.inc
|
|
require eglibc-ld.inc
|
|
require eglibc-testing.inc
|
|
|
|
STAGINGCC = "gcc-cross-initial"
|
|
STAGINGCC_virtclass-nativesdk = "gcc-crosssdk-initial"
|
|
PATH_prepend = "${STAGING_BINDIR_TOOLCHAIN}.${STAGINGCC}:"
|
|
|
|
TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TCBOOTSTRAP}"
|
|
|
|
# siteconfig.bbclass runs configure which needs a working compiler
|
|
# For the compiler to work we need a working libc yet libc isn't
|
|
# in the sysroots directory at this point. This means the libc.so
|
|
# linker script won't work as the --sysroot setting isn't correct.
|
|
# Here we create a hacked up libc linker script and pass in the right
|
|
# flags to let configure work. Ugly.
|
|
EXTRASITECONFIG = "CFLAGS='${CFLAGS} -Wl,-L${WORKDIR}/site_config_libc -L${WORKDIR}/site_config_libc -L${SYSROOT_DESTDIR}${libdir} -L${SYSROOT_DESTDIR}${base_libdir} -Wl,-L${SYSROOT_DESTDIR}${libdir} -Wl,-L${SYSROOT_DESTDIR}${base_libdir}'"
|
|
siteconfig_do_siteconfig_gencache_prepend = " \
|
|
mkdir -p ${WORKDIR}/site_config_libc; \
|
|
cp ${SYSROOT_DESTDIR}${libdir}/libc.so ${WORKDIR}/site_config_libc; \
|
|
sed -i -e 's# ${base_libdir}# ${SYSROOT_DESTDIR}${base_libdir}#g' -e 's# ${libdir}# ${SYSROOT_DESTDIR}${libdir}#g' ${WORKDIR}/site_config_libc/libc.so; \
|
|
"
|
|
|
|
# nptl needs unwind support in gcc, which can't be built without glibc.
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc-initial linux-libc-headers virtual/${TARGET_PREFIX}libc-initial"
|
|
# nptl needs libgcc but dlopens it, so our shlibs code doesn't detect this
|
|
#RDEPENDS_${PN} += "${@['','libgcc']['nptl' in '${GLIBC_ADDONS}']}"
|
|
PROVIDES = "virtual/libc virtual/${TARGET_PREFIX}libc-for-gcc"
|
|
PROVIDES += "virtual/libintl virtual/libiconv"
|
|
inherit autotools
|
|
require eglibc-options.inc
|
|
|
|
LEAD_SONAME = "libc.so"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_KSH=${base_bindir}/bash \
|
|
ac_cv_path_BASH_SHELL=${base_bindir}/bash \
|
|
libc_cv_localedir=${localedir} \
|
|
libc_cv_ssp=no \
|
|
"
|
|
|
|
GLIBC_EXTRA_OECONF ?= ""
|
|
GLIBC_EXTRA_OECONF_virtclass-nativesdk = ""
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
# eglibc uses PARALLELMFLAGS variable to pass parallel build info so transfer
|
|
# PARALLEL_MAKE into PARALLELMFLAGS and empty out PARALLEL_MAKE
|
|
EGLIBCPARALLELISM := "PARALLELMFLAGS="${PARALLEL_MAKE}""
|
|
EXTRA_OEMAKE[vardepsexclude] += "EGLIBCPARALLELISM"
|
|
EXTRA_OEMAKE += "${EGLIBCPARALLELISM}"
|
|
PARALLEL_MAKE = ""
|
|
|
|
# eglibc make-syscalls.sh has a number of issues with /bin/dash and
|
|
# it's output which make calls via the SHELL also has issues, so
|
|
# ensure make uses /bin/bash
|
|
EXTRA_OEMAKE += "SHELL=/bin/bash"
|
|
|
|
OE_FEATURES = "${@features_to_eglibc_settings(d)}"
|
|
do_configure_prepend() {
|
|
sed -e "s#@BASH@#/bin/sh#" -i ${S}/elf/ldd.bash.in
|
|
echo '${OE_FEATURES}' > ${B}/option-groups.config
|
|
}
|
|
|
|
do_configure_append() {
|
|
oe_runmake config
|
|
}
|
|
|
|
GLIBC_ADDONS ?= "ports,nptl,libidn"
|
|
SDK_GLIBC_ADDONS ?= "ports,nptl,libidn"
|
|
GLIBC_ADDONS_virtclass-nativesdk = "${SDK_GLIBC_ADDONS}"
|