mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 06:32:11 +02:00
ad23395cd1
As discussed on the mailing lists, using a suffix to package names is hard and has lead to many recipes having to do PKGSUFFIX games. Its looking extremely hard to scale nativesdk much further without hacking many recipes. By comparison, using a prefix like multilib does works much better and doesn't involve "hacking" as many recipes. This change converts nativesdk to use a prefix using the existing multilib infrastructure. (From OE-Core rev: 81813c0e322dc04ce4b069117188d8a54dfddb8c) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
66 lines
2.9 KiB
BlitzBasic
66 lines
2.9 KiB
BlitzBasic
SUMMARY = "Simple DirectMedia Layer"
|
|
DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
|
|
library designed to provide low level access to audio, keyboard, mouse, \
|
|
joystick, 3D hardware via OpenGL, and 2D video framebuffer."
|
|
HOMEPAGE = "http://www.libsdl.org"
|
|
BUGTRACKER = "http://bugzilla.libsdl.org/"
|
|
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=27818cd7fd83877a8e3ef82b82798ef4"
|
|
|
|
PROVIDES = "virtual/libsdl"
|
|
|
|
DEPENDS = "${@base_contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'opengl', 'virtual/libgl', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxext libxrandr libxrender', '', d)} \
|
|
tslib"
|
|
DEPENDS_virtclass-nativesdk = "${@base_contains('DISTRO_FEATURES', 'x11', 'nativesdk-libx11 nativesdk-libxrandr nativesdk-libxrender nativesdk-libxext', '', d)}"
|
|
|
|
PR = "r0"
|
|
|
|
SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \
|
|
file://configure_tweak.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/SDL-${PV}"
|
|
|
|
SRC_URI[md5sum] = "9d96df8417572a2afb781a7c4c811a85"
|
|
SRC_URI[sha256sum] = "d6d316a793e5e348155f0dd93b979798933fb98aa1edebcc108829d6474aad00"
|
|
|
|
inherit autotools lib_package binconfig pkgconfig
|
|
|
|
EXTRA_OECONF = "--disable-static --disable-debug --enable-cdrom --enable-threads --enable-timers --enable-endian \
|
|
--enable-file --disable-oss --disable-esd --disable-arts \
|
|
--disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
|
|
--disable-mintaudio --disable-nasm --disable-video-dga \
|
|
--disable-video-fbcon --disable-video-ps2gs --disable-video-ps3 \
|
|
--disable-video-xbios --disable-video-gem --disable-video-dummy \
|
|
--enable-input-events --enable-input-tslib --enable-pthreads \
|
|
${@base_contains('DISTRO_FEATURES', 'directfb', '--enable-video-directfb', '--disable-video-directfb', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'opengl', '--enable-video-opengl', '--disable-video-opengl', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', '--enable-video-x11', '--disable-video-x11', d)} \
|
|
--disable-video-svga \
|
|
--disable-video-picogui --disable-video-qtopia --enable-dlopen \
|
|
--disable-rpath \
|
|
--disable-pulseaudio"
|
|
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
|
|
PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib,"
|
|
|
|
PARALLEL_MAKE = ""
|
|
|
|
EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader"
|
|
|
|
do_configure_prepend() {
|
|
# Remove old libtool macros.
|
|
MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4"
|
|
for i in ${MACROS}; do
|
|
rm -f acinclude/$i
|
|
done
|
|
export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|