mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 17:09:42 +01:00
29d6678fd5
Having one monolithic packages directory makes it hard to find things and is generally overwhelming. This commit splits it into several logical sections roughly based on function, recipes.txt gives more information about the classifications used. The opportunity is also used to switch from "packages" to "recipes" as used in OpenEmbedded as the term "packages" can be confusing to people and has many different meanings. Not all recipes have been classified yet, this is just a first pass at separating things out. Some packages are moved to meta-extras as they're no longer actively used or maintained. Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
64 lines
1.8 KiB
BlitzBasic
64 lines
1.8 KiB
BlitzBasic
DESCRIPTION = "A collection of utilities and DSOs to handle compiled objects."
|
|
HOMEPAGE = "https://fedorahosted.org/elfutils"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2 with exceptions"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3\
|
|
file://EXCEPTION;md5=570adcb0c1218ab57f2249c67d0ce417"
|
|
DEPENDS = "libtool"
|
|
|
|
PR = "r1"
|
|
|
|
SRC_URI = "https://fedorahosted.org/releases/e/l/elfutils/elfutils-${PV}.tar.bz2"
|
|
|
|
# pick the patch from debian
|
|
# http://ftp.de.debian.org/debian/pool/main/e/elfutils/elfutils_0.148-1.debian.tar.gz
|
|
|
|
SRC_URI += "\
|
|
file://redhat-portability.diff \
|
|
file://redhat-robustify.diff \
|
|
file://hppa_backend.diff \
|
|
file://arm_backend.diff \
|
|
file://mips_backend.diff \
|
|
file://m68k_backend.diff \
|
|
file://do-autoreconf.diff \
|
|
file://testsuite-ignore-elflint.diff \
|
|
file://elf_additions.diff \
|
|
file://elfutils-fsize.patch \
|
|
"
|
|
|
|
# The buildsystem wants to generate 2 .h files from source using a binary it just built,
|
|
# which can not pass the cross compiling, so let's work around it by adding 2 .h files
|
|
# along with the do_configure_prepend()
|
|
|
|
SRC_URI += "\
|
|
file://i386_dis.h \
|
|
file://x86_64_dis.h \
|
|
"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF = "--program-prefix=eu-"
|
|
|
|
do_configure_prepend() {
|
|
sed -i 's:./i386_gendis:echo\ \#:g' ${S}/libcpu/Makefile.am
|
|
|
|
cp ${WORKDIR}/*dis.h ${S}/libcpu
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Package utilities separately
|
|
PACKAGES =+ "${PN}-binutils"
|
|
FILES_${PN}-binutils = "\
|
|
${bindir}/eu-addr2line \
|
|
${bindir}/eu-ld \
|
|
${bindir}/eu-nm \
|
|
${bindir}/eu-readelf \
|
|
${bindir}/eu-size \
|
|
${bindir}/eu-strip"
|
|
# Fix library issues
|
|
FILES_${PN} =+ "${libdir}/*-${PV}.so"
|
|
|
|
# The elfutils package contains symlinks that trip up insane
|
|
INSANE_SKIP_elfutils = "1"
|