mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 02:33:02 +01:00
d07fba12a0
goarch is used in all classes of recipes ranging from native to target,
therefore its best to contain the variables and not spill over into
recipe classes where they can adversely affect shared state reuse e.g.
go-native currently gets TUNE_FEATURES into dependency chain of
referenced variables which means go-native gets rebuilt when we change
from qemuarm to qemux86 machine types since TUNE_FEATURES is defined
with DEFAULTTUNE which would change as machines are switched
These variables are specific to arm/mips/x86 so marking them with
appropriate overrides for native recipes will be right thing here
Chose 'hardfloat' for mips which is default too, 7 for arm and sse2 for x86
somehow go-native bootstrap compiler (1.4) still needs them so feed
commonly used values or defaults.
Fixes
ERROR: go-native different signature for task do_configure.sigdata between qemux86copy and qemuarm
...
List of dependencies for variable TUNE_FEATURES changed from '{'DEFAULTTUNE', 'TUNE_FEATURES_tune-core2-32'}' to '{'DEFAULTTUNE', 'TUNE_FEATURES_tune-armv7vethf-neon'}'
changed items: {'TUNE_FEATURES_tune-core2-32', 'TUNE_FEATURES_tune-armv7vethf-neon'}
(From OE-Core rev: 83eebf5577dd0a23be937375c1a8a15e3da4fa64)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
119 lines
3.6 KiB
Plaintext
119 lines
3.6 KiB
Plaintext
BUILD_GOOS = "${@go_map_os(d.getVar('BUILD_OS'), d)}"
|
|
BUILD_GOARCH = "${@go_map_arch(d.getVar('BUILD_ARCH'), d)}"
|
|
BUILD_GOTUPLE = "${BUILD_GOOS}_${BUILD_GOARCH}"
|
|
HOST_GOOS = "${@go_map_os(d.getVar('HOST_OS'), d)}"
|
|
HOST_GOARCH = "${@go_map_arch(d.getVar('HOST_ARCH'), d)}"
|
|
HOST_GOARM = "${@go_map_arm(d.getVar('HOST_ARCH'), d)}"
|
|
HOST_GO386 = "${@go_map_386(d.getVar('HOST_ARCH'), d.getVar('TUNE_FEATURES'), d)}"
|
|
HOST_GOMIPS = "${@go_map_mips(d.getVar('HOST_ARCH'), d.getVar('TUNE_FEATURES'), d)}"
|
|
HOST_GOARM_class-native = "7"
|
|
HOST_GO386_class-native = "sse2"
|
|
HOST_GOMIPS_class-native = "hardfloat"
|
|
HOST_GOTUPLE = "${HOST_GOOS}_${HOST_GOARCH}"
|
|
TARGET_GOOS = "${@go_map_os(d.getVar('TARGET_OS'), d)}"
|
|
TARGET_GOARCH = "${@go_map_arch(d.getVar('TARGET_ARCH'), d)}"
|
|
TARGET_GOARM = "${@go_map_arm(d.getVar('TARGET_ARCH'), d)}"
|
|
TARGET_GO386 = "${@go_map_386(d.getVar('TARGET_ARCH'), d.getVar('TUNE_FEATURES'), d)}"
|
|
TARGET_GOMIPS = "${@go_map_mips(d.getVar('TARGET_ARCH'), d.getVar('TUNE_FEATURES'), d)}"
|
|
TARGET_GOARM_class-native = "7"
|
|
TARGET_GO386_class-native = "sse2"
|
|
TARGET_GOMIPS_class-native = "hardfloat"
|
|
TARGET_GOTUPLE = "${TARGET_GOOS}_${TARGET_GOARCH}"
|
|
GO_BUILD_BINDIR = "${@['bin/${HOST_GOTUPLE}','bin'][d.getVar('BUILD_GOTUPLE') == d.getVar('HOST_GOTUPLE')]}"
|
|
|
|
# Use the MACHINEOVERRIDES to map ARM CPU architecture passed to GO via GOARM.
|
|
# This is combined with *_ARCH to set HOST_GOARM and TARGET_GOARM.
|
|
BASE_GOARM = ''
|
|
BASE_GOARM_armv7ve = '7'
|
|
BASE_GOARM_armv7a = '7'
|
|
BASE_GOARM_armv6 = '6'
|
|
BASE_GOARM_armv5 = '5'
|
|
|
|
# Go supports dynamic linking on a limited set of architectures.
|
|
# See the supportsDynlink function in go/src/cmd/compile/internal/gc/main.go
|
|
GO_DYNLINK = ""
|
|
GO_DYNLINK_arm = "1"
|
|
GO_DYNLINK_aarch64 = "1"
|
|
GO_DYNLINK_x86 = "1"
|
|
GO_DYNLINK_x86-64 = "1"
|
|
GO_DYNLINK_powerpc64 = "1"
|
|
GO_DYNLINK_class-native = ""
|
|
GO_DYNLINK_class-nativesdk = ""
|
|
|
|
# define here because everybody inherits this class
|
|
#
|
|
COMPATIBLE_HOST_linux-gnux32 = "null"
|
|
COMPATIBLE_HOST_linux-muslx32 = "null"
|
|
COMPATIBLE_HOST_powerpc = "null"
|
|
COMPATIBLE_HOST_powerpc64 = "null"
|
|
COMPATIBLE_HOST_mipsarchn32 = "null"
|
|
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
ARM_INSTRUCTION_SET_armv6 = "arm"
|
|
|
|
TUNE_CCARGS_remove = "-march=mips32r2"
|
|
SECURITY_CFLAGS_mipsarch = "${SECURITY_NOPIE_CFLAGS}"
|
|
SECURITY_NOPIE_CFLAGS ??= ""
|
|
|
|
# go can't be built with ccache:
|
|
# gcc: fatal error: no input files
|
|
CCACHE_DISABLE ?= "1"
|
|
|
|
def go_map_arch(a, d):
|
|
import re
|
|
if re.match('i.86', a):
|
|
return '386'
|
|
elif a == 'x86_64':
|
|
return 'amd64'
|
|
elif re.match('arm.*', a):
|
|
return 'arm'
|
|
elif re.match('aarch64.*', a):
|
|
return 'arm64'
|
|
elif re.match('mips64el.*', a):
|
|
return 'mips64le'
|
|
elif re.match('mips64.*', a):
|
|
return 'mips64'
|
|
elif a == 'mips':
|
|
return 'mips'
|
|
elif a == 'mipsel':
|
|
return 'mipsle'
|
|
elif re.match('p(pc|owerpc)(64)', a):
|
|
return 'ppc64'
|
|
elif re.match('p(pc|owerpc)(64el)', a):
|
|
return 'ppc64le'
|
|
elif a == 'riscv64':
|
|
return 'riscv64'
|
|
else:
|
|
raise bb.parse.SkipRecipe("Unsupported CPU architecture: %s" % a)
|
|
|
|
def go_map_arm(a, d):
|
|
if a.startswith("arm"):
|
|
return d.getVar('BASE_GOARM')
|
|
return ''
|
|
|
|
def go_map_386(a, f, d):
|
|
import re
|
|
if re.match('i.86', a):
|
|
if ('core2' in f) or ('corei7' in f):
|
|
return 'sse2'
|
|
else:
|
|
return '387'
|
|
return ''
|
|
|
|
def go_map_mips(a, f, d):
|
|
import re
|
|
if a == 'mips' or a == 'mipsel':
|
|
if 'fpu-hard' in f:
|
|
return 'hardfloat'
|
|
else:
|
|
return 'softfloat'
|
|
return ''
|
|
|
|
def go_map_os(o, d):
|
|
if o.startswith('linux'):
|
|
return 'linux'
|
|
return o
|
|
|
|
|