mirror of
https://git.yoctoproject.org/poky
synced 2026-03-02 05:19:40 +01:00
73d1967498
0001-Add-missing-prototypes-to-function-declarations.patch makefile-no-rebuild.patch refreshed for 3.3.0 Changelog: ========== - Fixed a bug with '--sparse --inplace' where a trailing gap in the source file would not clear out the trailing data in the destination file. - Fixed an buffer overflow in the checksum2 code if SHA1 is being used for the checksum2 algorithm. - Fixed an issue when rsync is compiled using '_FORTIFY_SOURCE' so that the extra tests don't complain about a strlcpy() limit value (which was too large, even though it wasn't possible for the larger value to cause an overflow). - Add a backtick to the list of characters that the filename quoting needs to escape using backslashes. - Fixed a string-comparison issue in the internal handling of '--progress' (a locale such as tr_TR.utf-8 needed the internal triggering of '--info' options to use upper-case flag names to ensure that they match). - Make sure that a local transfer marks the sender side as trusted. - Change the argv handling to work with a newer popt library -- one that likes to free more data than it used to. - Rsync now calls 'OpenSSL_add_all_algorithms()' when compiled against an older openssl library. - Fixed a problem in the daemon auth for older protocols (29 and before) if the openssl library is being used to compute MD4 checksums. - Fixed 'rsync -VV' on Cygwin -- it needed a flush of stdout. - Fixed an old stats bug that counted devices as symlinks. (From OE-Core rev: 2c3b75a1f3b6d3177603b8982d61c5b8ba73aef0) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.7 KiB
BlitzBasic
68 lines
2.7 KiB
BlitzBasic
SUMMARY = "File synchronization tool"
|
|
HOMEPAGE = "http://rsync.samba.org/"
|
|
DESCRIPTION = "rsync is an open source utility that provides fast incremental file transfer."
|
|
BUGTRACKER = "http://rsync.samba.org/bugzilla.html"
|
|
SECTION = "console/network"
|
|
# GPL-2.0-or-later (<< 3.0.0), GPL-3.0-or-later (>= 3.0.0)
|
|
# Includes opennsh and xxhash dynamic link exception
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=24423708fe159c9d12be1ea29fcb18c7"
|
|
|
|
DEPENDS = "popt"
|
|
|
|
SRC_URI = "https://download.samba.org/pub/${BPN}/src/${BP}.tar.gz \
|
|
file://rsyncd.conf \
|
|
file://makefile-no-rebuild.patch \
|
|
file://determism.patch \
|
|
file://0001-Add-missing-prototypes-to-function-declarations.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "7399e9a6708c32d678a72a63219e96f23be0be2336e50fd1348498d07041df90"
|
|
|
|
inherit autotools-brokensep
|
|
|
|
PACKAGECONFIG ??= "acl attr \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[acl] = "--enable-acl-support,--disable-acl-support,acl,"
|
|
PACKAGECONFIG[attr] = "--enable-xattr-support,--disable-xattr-support,attr,"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
PACKAGECONFIG[lz4] = "--enable-lz4,--disable-lz4,lz4"
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
PACKAGECONFIG[xxhash] = "--enable-xxhash,--disable-xxhash,xxhash"
|
|
PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd"
|
|
|
|
# By default, if crosscompiling, rsync disables a number of
|
|
# capabilities, hardlinking symlinks and special files (i.e. devices)
|
|
CACHED_CONFIGUREVARS += "rsync_cv_can_hardlink_special=yes rsync_cv_can_hardlink_symlink=yes"
|
|
|
|
EXTRA_OEMAKE = 'STRIP=""'
|
|
EXTRA_OECONF = "--disable-md2man --with-nobody-group=nogroup"
|
|
|
|
#| ./simd-checksum-x86_64.cpp: In function 'uint32_t get_checksum1_cpp(char*, int32_t)':
|
|
#| ./simd-checksum-x86_64.cpp:89:52: error: multiversioning needs 'ifunc' which is not supported on this target
|
|
#| 89 | __attribute__ ((target("default"))) MVSTATIC int32 get_checksum1_avx2_64(schar* buf, int32 len, int32 i, uint32* ps1, uint32* ps2) { return i; }
|
|
#| | ^~~~~~~~~~~~~~~~~~~~~
|
|
#| ./simd-checksum-x86_64.cpp:480:1: error: use of multiversioned function without a default
|
|
#| 480 | }
|
|
#| | ^
|
|
#| If you can't fix the issue, re-run ./configure with --disable-roll-simd.
|
|
EXTRA_OECONF:append:libc-musl = " --disable-roll-simd"
|
|
|
|
# rsync 3.0 uses configure.sh instead of configure, and
|
|
# makefile checks the existence of configure.sh
|
|
do_configure:prepend () {
|
|
rm -f ${S}/configure ${S}/configure.sh
|
|
}
|
|
|
|
do_configure:append () {
|
|
cp -f ${S}/configure ${S}/configure.sh
|
|
}
|
|
|
|
do_install:append() {
|
|
install -d ${D}${sysconfdir}
|
|
install -m 0644 ${WORKDIR}/rsyncd.conf ${D}${sysconfdir}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|