mirror of
https://git.yoctoproject.org/poky
synced 2026-05-04 13:39:49 +02:00
c76f119db8
Drop patches: parallel.patch (obsolete as no .a files are installed) 0001-intl-Fix-build-failure-with-make-j.patch (backport) Gettext no longer installs anything into $libdir/gettext by default but still creates the directory and so it should be packaged. (From OE-Core rev: a414f47009811fa6886e43fd2b4c928a906a65f3) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.6 KiB
BlitzBasic
47 lines
1.6 KiB
BlitzBasic
SUMMARY = "Minimal gettext for supporting native autoconf/automake"
|
|
DESCRIPTION = "Contains the m4 macros sufficient to support building \
|
|
autoconf/automake. This provides a significant build time speedup by \
|
|
the removal of gettext-native from most dependency chains (now only \
|
|
needed for gettext for the target)."
|
|
|
|
require gettext-sources.inc
|
|
SRC_URI += " \
|
|
file://COPYING \
|
|
"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
INHIBIT_AUTOTOOLS_DEPS = "1"
|
|
|
|
LICENSE = "FSF-Unlimited"
|
|
LIC_FILES_CHKSUM = "file://${UNPACKDIR}/COPYING;md5=4bd090a20bfcd1a18f1f79837b5e3e91"
|
|
|
|
inherit native
|
|
|
|
S = "${WORKDIR}/gettext-${PV}"
|
|
|
|
python get_aclocal_files() {
|
|
fpath = oe.path.join(d.getVar("S"), "/gettext-tools/m4/Makefile.am")
|
|
with open(fpath) as f:
|
|
content = f.read()
|
|
for l in content.replace("\\\n","").split("\n"):
|
|
if l.startswith("aclocal_DATA"):
|
|
aclocal_files = l.split("=")[1]
|
|
with open(oe.path.join(d.getVar("WORKDIR"),"aclocal-files"),'w') as outf:
|
|
outf.write(aclocal_files)
|
|
break
|
|
else:
|
|
bb.error("Could not obtain list of installed aclocal files from {}".format(fpath))
|
|
}
|
|
do_install[prefuncs] += "get_aclocal_files"
|
|
|
|
do_install () {
|
|
install -d ${D}${datadir}/aclocal/
|
|
for i in `cat ${WORKDIR}/aclocal-files`; do
|
|
cp ${S}/gettext-tools/m4/$i ${D}${datadir}/aclocal/
|
|
done
|
|
install -d ${D}${datadir}/gettext/po/
|
|
cp ${S}/build-aux/config.rpath ${D}${datadir}/gettext/
|
|
cp ${S}/gettext-runtime/po/Makefile.in.in ${D}${datadir}/gettext/po/
|
|
cp ${S}/gettext-runtime/po/remove-potcdate.sed ${D}${datadir}/gettext/po/
|
|
}
|