mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
eedae071c7
Provide both a 3.0.x and a 3.1 set of headers to the toolchain. Compatibility is maintained with older 2.6 headers by creating a new variable that changes the SRC_URI based on the major version number of the kernel. Built and booted with 2.6.37.2, 3.0.8 and 3.1 linux-libc-headers. (From OE-Core rev: 13c233ce4551542481d7a6390ff2119671137b95) Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
67 lines
1.5 KiB
PHP
67 lines
1.5 KiB
PHP
DESCRIPTION = "Sanitized set of kernel headers for the C library's use."
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
|
|
|
|
python __anonymous () {
|
|
major = d.getVar("PV",True).split('.')[0]
|
|
if major == "3":
|
|
d.setVar("HEADER_FETCH_VER", "3.0")
|
|
else:
|
|
d.setVar("HEADER_FETCH_VER", "2.6")
|
|
}
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/kernel/v${HEADER_FETCH_VER}/linux-${PV}.tar.bz2"
|
|
|
|
S = "${WORKDIR}/linux-${PV}"
|
|
|
|
set_arch() {
|
|
case ${TARGET_ARCH} in
|
|
alpha*) ARCH=alpha ;;
|
|
arm*) ARCH=arm ;;
|
|
cris*) ARCH=cris ;;
|
|
hppa*) ARCH=parisc ;;
|
|
i*86*) ARCH=i386 ;;
|
|
ia64*) ARCH=ia64 ;;
|
|
mips*) ARCH=mips ;;
|
|
m68k*) ARCH=m68k ;;
|
|
powerpc*) ARCH=powerpc ;;
|
|
s390*) ARCH=s390 ;;
|
|
sh*) ARCH=sh ;;
|
|
sparc64*) ARCH=sparc64 ;;
|
|
sparc*) ARCH=sparc ;;
|
|
x86_64*) ARCH=x86_64 ;;
|
|
avr32*) ARCH=avr32 ;;
|
|
bfin*) ARCH=blackfin ;;
|
|
microblaze*) ARCH=microblaze ;;
|
|
esac
|
|
}
|
|
|
|
do_configure() {
|
|
set_arch
|
|
oe_runmake allnoconfig ARCH=$ARCH
|
|
}
|
|
|
|
do_compile () {
|
|
}
|
|
|
|
do_install() {
|
|
set_arch
|
|
oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
|
|
# Kernel should not be exporting this header
|
|
rm -f ${D}${exec_prefix}/include/scsi/scsi.h
|
|
|
|
# The ..install.cmd conflicts between various configure runs
|
|
find ${D}${includedir} -name ..install.cmd | xargs rm -f
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
#DEPENDS = "cross-linkage"
|
|
RDEPENDS_${PN}-dev = ""
|
|
RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPKGV})"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS += "unifdef-native"
|