mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 09:49:41 +01:00
1a82468d2d
By default GOCACHE is set to $HOME/.cache. Fixes: ERROR: go-cross-dbfp4-1.12.1-r0 do_compile: Function failed: do_compile (log file is located at /workdir/build/tmp/work/x86_64-linux/go-cross-dbfp4/1.12.1-r0/temp/log.do_compile.8120) ERROR: Logfile of failure stored in: /workdir/build/tmp/work/x86_64-linux/go-cross-dbfp4/1.12.1-r0/temp/log.do_compile.8120 Log data follows: | DEBUG: Executing shell function do_compile | Building Go cmd/dist using /workdir/build/tmp/work/x86_64-linux/go-cross-dbfp4/1.12.1-r0/recipe-sysroot-native/usr/lib/go. | failed to initialize build cache at /home/pokyuser/.cache/go-build: mkdir /home/pokyuser/.cache: permission denied | WARNING: exit code 1 from a shell command. | ERROR: Function failed: do_compile (log file is located at /workdir/build/tmp/work/x86_64-linux/go-cross-dbfp4/1.12.1-r0/temp/log.do_compile.8120) ERROR: Task (/workdir/repo/poky/meta/recipes-devtools/go/go-cross_1.12.bb:do_compile) failed with exit code '1' NOTE: Tasks Summary: Attempted 23 tasks of which 16 didn't need to be rerun and 1 failed. (From OE-Core rev: 9a6d208b9979035bbfc1def80fb6558db4bddb12) Signed-off-by: Ricardo Ribalda Delgado <ricardo@ribalda.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.7 KiB
PHP
55 lines
1.7 KiB
PHP
DEPENDS = "virtual/${TUNE_PKGARCH}-go go-native"
|
|
DEPENDS_class-nativesdk = "virtual/${TARGET_PREFIX}go-crosssdk go-native"
|
|
|
|
export GOHOSTOS = "${BUILD_GOOS}"
|
|
export GOHOSTARCH = "${BUILD_GOARCH}"
|
|
export GOOS = "${TARGET_GOOS}"
|
|
export GOARCH = "${TARGET_GOARCH}"
|
|
export GOARM = "${TARGET_GOARM}"
|
|
export GO386 = "${TARGET_GO386}"
|
|
export GOMIPS = "${TARGET_GOMIPS}"
|
|
export GOROOT_BOOTSTRAP = "${STAGING_LIBDIR_NATIVE}/go"
|
|
export GOROOT_FINAL = "${libdir}/go"
|
|
export GOCACHE = "${B}/.cache"
|
|
GO_LDFLAGS = ""
|
|
GO_LDFLAGS_class-nativesdk = "-linkmode external"
|
|
export GO_LDFLAGS
|
|
|
|
CC_append_class-nativesdk = " ${SECURITY_NOPIE_CFLAGS}"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile() {
|
|
export CC_FOR_${TARGET_GOOS}_${TARGET_GOARCH}="${CC}"
|
|
export CXX_FOR_${TARGET_GOOS}_${TARGET_GOARCH}="${CXX}"
|
|
|
|
cd src
|
|
./make.bash --target-only --no-banner
|
|
cd ${B}
|
|
}
|
|
do_compile[dirs] =+ "${GOTMPDIR} ${B}/bin ${B}/pkg"
|
|
do_compile[cleandirs] += "${GOTMPDIR} ${B}/bin ${B}/pkg"
|
|
|
|
do_install() {
|
|
install -d ${D}${libdir}/go/pkg/tool
|
|
cp --preserve=mode,timestamps -R ${B}/pkg/tool/${TARGET_GOTUPLE} ${D}${libdir}/go/pkg/tool/
|
|
install -d ${D}${libdir}/go/src
|
|
cp --preserve=mode,timestamps -R ${S}/src/cmd ${D}${libdir}/go/src/
|
|
find ${D}${libdir}/go/src -depth -type d -name testdata -exec rm -rf {} \;
|
|
install -d ${D}${libdir}/go/bin
|
|
install -d ${D}${bindir}
|
|
for f in ${B}/${GO_BUILD_BINDIR}/*; do
|
|
name=`basename $f`
|
|
install -m 0755 $f ${D}${libdir}/go/bin/
|
|
ln -sf ../${baselib}/go/bin/$name ${D}${bindir}/
|
|
done
|
|
}
|
|
|
|
PACKAGES = "${PN} ${PN}-dev"
|
|
FILES_${PN} = "${libdir}/go/bin ${libdir}/go/pkg/tool/${TARGET_GOTUPLE} ${bindir}"
|
|
FILES_${PN}-dev = "${libdir}/go"
|
|
RDEPENDS_${PN}-dev = "perl bash"
|
|
INSANE_SKIP_${PN} = "ldflags"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|