mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
0e599227ee
Although glx support is turned off, the build still tries to pull in some x11 components, disable x11 explicitly. (From OE-Core rev: a96272dc0b5b6b76a4858981461f3bd126dc99b3) Signed-off-by: Andrew F. Davis <afd@ti.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.3 KiB
BlitzBasic
39 lines
1.3 KiB
BlitzBasic
SUMMARY = "OpenGL function pointer management library"
|
|
HOMEPAGE = "https://github.com/anholt/libepoxy/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=58ef4c80d401e07bd9ee8b6b58cf464b"
|
|
|
|
SRC_URI = "https://github.com/anholt/${BPN}/releases/download/${PV}/${BP}.tar.xz \
|
|
"
|
|
SRC_URI[md5sum] = "e2845de8d2782b2d31c01ae8d7cd4cbb"
|
|
SRC_URI[sha256sum] = "002958c5528321edd53440235d3c44e71b5b1e09b9177e8daf677450b6c4433d"
|
|
UPSTREAM_CHECK_URI = "https://github.com/anholt/libepoxy/releases"
|
|
|
|
inherit meson pkgconfig distro_features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "opengl"
|
|
REQUIRED_DISTRO_FEATURES_class-native = ""
|
|
REQUIRED_DISTRO_FEATURES_class-nativesdk = ""
|
|
|
|
PACKAGECONFIG[egl] = "-Degl=yes, -Degl=no, virtual/egl"
|
|
PACKAGECONFIG[x11] = "-Dglx=yes, -Dglx=no -Dx11=false, virtual/libx11 virtual/libgl"
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} egl"
|
|
|
|
EXTRA_OEMESON += "-Dtests=false"
|
|
|
|
PACKAGECONFIG_class-native = "egl x11"
|
|
PACKAGECONFIG_class-nativesdk = "egl x11"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# This will ensure that dlopen will attempt only GL libraries provided by host
|
|
do_install_append_class-native() {
|
|
chrpath --delete ${D}${libdir}/*.so
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
chrpath --delete ${D}${libdir}/*.so
|
|
}
|