mirror of
https://git.yoctoproject.org/poky
synced 2026-04-28 06:32:34 +02:00
17dab68520
Vulkan tools and utilities that can assist development by enabling developers to verify their applications correct use of the Vulkan API. DEPENDS on vulkan-headers and vulkan-loader. (From OE-Core rev: c4db69fc0d8d46a396ee744fddad0300ec730f46) Signed-off-by: Tim Orling <timothy.t.orling@linux.intel.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
32 lines
1.2 KiB
BlitzBasic
32 lines
1.2 KiB
BlitzBasic
SUMMARY = "Vulkan Utilities and Tools"
|
|
HOMEPAGE = "https://www.khronos.org/vulkan/"
|
|
BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-Tools"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
SRC_URI = "git://github.com/KhronosGroup/Vulkan-Tools.git;branch=sdk-${PV}"
|
|
SRCREV = "3ccd7f6ebae3e1919adf837718c04feb6c2acc61"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake distro_features_check
|
|
ANY_OF_DISTRO_FEATURES = "x11 wayland"
|
|
REQUIRED_DISTRO_FEATURES = "vulkan"
|
|
|
|
DEPENDS += "vulkan-headers vulkan-loader"
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_TESTS=OFF \
|
|
-DBUILD_CUBE=OFF \
|
|
-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
|
|
"
|
|
|
|
# must choose x11 or wayland or both
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
|
|
PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
|