mirror of
https://git.yoctoproject.org/poky
synced 2026-02-23 01:49:40 +01:00
4977a0743b
The code that utilized them was superseded by the code (in the same patch!) that is utilizing STAGING_LIBDIR/STAGING_INCDIR, and wasn't correct in the first place as HOST_SYS is not necessarily the same as the sysroot directory name. (From OE-Core rev: 8834e81a38c24a066bb4fefa93da61011d0db244) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
2.0 KiB
Plaintext
46 lines
2.0 KiB
Plaintext
# Inherit this class in recipes to enable building their introspection files
|
|
|
|
# This sets up autoconf-based recipes to build introspection data (or not),
|
|
# depending on distro and machine features (see gobject-introspection-data class).
|
|
inherit gobject-introspection-data
|
|
EXTRA_OECONF_prepend_class-target = "${@bb.utils.contains('GI_DATA_ENABLED', 'True', '--enable-introspection', '--disable-introspection', d)} "
|
|
|
|
# When building native recipes, disable introspection, as it is not necessary,
|
|
# pulls in additional dependencies, and makes build times longer
|
|
EXTRA_OECONF_prepend_class-native = "--disable-introspection "
|
|
EXTRA_OECONF_prepend_class-nativesdk = "--disable-introspection "
|
|
|
|
UNKNOWN_CONFIGURE_WHITELIST_append = " --enable-introspection --disable-introspection"
|
|
|
|
# Generating introspection data depends on a combination of native and target
|
|
# introspection tools, and qemu to run the target tools.
|
|
DEPENDS_append_class-target = " gobject-introspection gobject-introspection-native qemu-native"
|
|
|
|
# Even though introspection is disabled on -native, gobject-introspection package is still
|
|
# needed for m4 macros.
|
|
DEPENDS_append_class-native = " gobject-introspection-native"
|
|
DEPENDS_append_class-nativesdk = " gobject-introspection-native"
|
|
|
|
# This is necessary for python scripts to succeed - distutils fails if these
|
|
# are not set
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
|
|
# This is used by introspection tools to find .gir includes
|
|
export XDG_DATA_DIRS = "${STAGING_DATADIR}"
|
|
|
|
do_configure_prepend_class-target () {
|
|
# introspection.m4 pre-packaged with upstream tarballs does not yet
|
|
# have our fixes
|
|
mkdir -p ${S}/m4
|
|
cp ${STAGING_DIR_TARGET}/${datadir}/aclocal/introspection.m4 ${S}/m4
|
|
}
|
|
|
|
# .typelib files are needed at runtime and so they go to the main package (so
|
|
# they'll be together with libraries they support).
|
|
FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib"
|
|
|
|
# .gir files go to dev package, as they're needed for developing (but not for
|
|
# running) things that depends on introspection.
|
|
FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir"
|