mirror of
https://git.yoctoproject.org/poky
synced 2026-04-23 00:32:12 +02:00
ec14a3ed28
Upgrade to latest 1.22.x release [1]: $ git --no-pager log --oneline go1.22.9..go1.22.10 8f3f22eef8 (tag: go1.22.10) [release-branch.go1.22] go1.22.10 6d7a95abca [release-branch.go1.22] runtime: reserve 4kB for system stack on windows-386 6f05fa7a4f [release-branch.go1.22] syscall: mark SyscallN as noescape 3355db9690 [release-branch.go1.22] time: accept "+01" in TestLoadFixed on OpenBSD [1] https://github.com/golang/go/compare/go1.22.9...go1.22.10 (From OE-Core rev: e357c93b39df938dc36195dbd779a58b2951b8e6) (From OE-Core rev: d723fa3573d02cc815ad9706aafd7510eb54eac6) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Steve Sakoman <steve@sakoman.com>
51 lines
1.4 KiB
BlitzBasic
51 lines
1.4 KiB
BlitzBasic
# This recipe is for bootstrapping our go-cross from a prebuilt binary of Go from golang.org.
|
|
|
|
SUMMARY = "Go programming language compiler (upstream binary for bootstrap)"
|
|
HOMEPAGE = " http://golang.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5d4950ecb7b26d2c5e4e7b4e0dd74707"
|
|
|
|
PROVIDES = "go-native"
|
|
|
|
# Checksums available at https://go.dev/dl/
|
|
SRC_URI = "https://dl.google.com/go/go${PV}.${BUILD_GOOS}-${BUILD_GOARCH}.tar.gz;name=go_${BUILD_GOTUPLE}"
|
|
SRC_URI[go_linux_amd64.sha256sum] = "736ce492a19d756a92719a6121226087ccd91b652ed5caec40ad6dbfb2252092"
|
|
SRC_URI[go_linux_arm64.sha256sum] = "5213c5e32fde3bd7da65516467b7ffbfe40d2bb5a5f58105e387eef450583eec"
|
|
SRC_URI[go_linux_ppc64le.sha256sum] = "db05b9838f69d741fb9a5301220b1a62014aee025b0baf341aba3d280087b981"
|
|
|
|
UPSTREAM_CHECK_URI = "https://golang.org/dl/"
|
|
UPSTREAM_CHECK_REGEX = "go(?P<pver>\d+(\.\d+)+)\.linux"
|
|
|
|
CVE_PRODUCT = "golang:go"
|
|
|
|
S = "${WORKDIR}/go"
|
|
|
|
inherit goarch native
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
make_wrapper() {
|
|
rm -f ${D}${bindir}/$1
|
|
cat <<END >${D}${bindir}/$1
|
|
#!/bin/bash
|
|
here=\`dirname \$0\`
|
|
export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
|
|
\$here/../lib/go/bin/$1 "\$@"
|
|
END
|
|
chmod +x ${D}${bindir}/$1
|
|
}
|
|
|
|
do_install() {
|
|
find ${S} -depth -type d -name testdata -exec rm -rf {} +
|
|
|
|
install -d ${D}${bindir} ${D}${libdir}/go
|
|
cp --preserve=mode,timestamps -R ${S}/ ${D}${libdir}/
|
|
|
|
for f in ${S}/bin/*
|
|
do
|
|
make_wrapper `basename $f`
|
|
done
|
|
}
|