mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 17:26:36 +01:00
f604ff9de4
Openssh (main) package may be marked for installation via complementary packages mechanism if sftp-server is installed and this causes conflict with dropbear [Yocto #14858] [1]. Excluding openssh complementary packages if packagegroup-core-ssh-dropbear is in PACKAGE_INSTALL fixes this issue. To install openssh complementary packages in the images with ssh-server-dropbear they may be added manually into the list because they will be excluded from the installation even if corresonding class (dev-pkg or dbg-pkgs) inherited. [1] Error: Problem: problem with installed package dropbear-2020.81-r0.core2_64 - package dropbear-2020.81-r0.core2_64 conflicts with openssh provided by openssh-8.9p1-r0.core2_64 - package openssh-8.9p1-r0.core2_64 conflicts with dropbear provided by dropbear-2020.81-r0.core2_64 - package openssh-ptest-8.9p1-r0.core2_64 requires openssh, but none of the providers can be installed - conflicting requests (try to add '--allowerasing' to command line to replace conflicting packages or '--skip-broken' to skip uninstallable packages) (From OE-Core rev: a09725442d4b53bb9d417ef9f43b12db2545aa54) Signed-off-by: Pavel Zhukov <pavel@zhukoff.net> Signed-off-by: Pavel Zhukov <pavel.zhukov@huawei.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit fa08030b32c2bf77889c23f964892f46e84994a3) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
84 lines
3.9 KiB
Plaintext
84 lines
3.9 KiB
Plaintext
# Common code for generating core reference images
|
|
#
|
|
# Copyright (C) 2007-2011 Linux Foundation
|
|
|
|
# IMAGE_FEATURES control content of the core reference images
|
|
#
|
|
# By default we install packagegroup-core-boot and packagegroup-base-extended packages;
|
|
# this gives us working (console only) rootfs.
|
|
#
|
|
# Available IMAGE_FEATURES:
|
|
#
|
|
# - weston - Weston Wayland compositor
|
|
# - x11 - X server
|
|
# - x11-base - X server with minimal environment
|
|
# - x11-sato - OpenedHand Sato environment
|
|
# - tools-debug - debugging tools
|
|
# - eclipse-debug - Eclipse remote debugging support
|
|
# - tools-profile - profiling tools
|
|
# - tools-testapps - tools usable to make some device tests
|
|
# - tools-sdk - SDK (C/C++ compiler, autotools, etc.)
|
|
# - nfs-server - NFS server
|
|
# - nfs-client - NFS client
|
|
# - ssh-server-dropbear - SSH server (dropbear)
|
|
# - ssh-server-openssh - SSH server (openssh)
|
|
# - hwcodecs - Install hardware acceleration codecs
|
|
# - package-management - installs package management tools and preserves the package manager database
|
|
# - debug-tweaks - makes an image suitable for development, e.g. allowing passwordless root logins
|
|
# - empty-root-password
|
|
# - allow-empty-password
|
|
# - allow-root-login
|
|
# - post-install-logging
|
|
# - dev-pkgs - development packages (headers, etc.) for all installed packages in the rootfs
|
|
# - dbg-pkgs - debug symbol packages for all installed packages in the rootfs
|
|
# - lic-pkgs - license packages for all installed pacakges in the rootfs, requires
|
|
# LICENSE_CREATE_PACKAGE="1" to be set when building packages too
|
|
# - doc-pkgs - documentation packages for all installed packages in the rootfs
|
|
# - bash-completion-pkgs - bash-completion packages for recipes using bash-completion bbclass
|
|
# - ptest-pkgs - ptest packages for all ptest-enabled recipes
|
|
# - read-only-rootfs - tweaks an image to support read-only rootfs
|
|
# - stateless-rootfs - systemctl-native not run, image populated by systemd at runtime
|
|
# - splash - bootup splash screen
|
|
#
|
|
FEATURE_PACKAGES_weston = "packagegroup-core-weston"
|
|
FEATURE_PACKAGES_x11 = "packagegroup-core-x11"
|
|
FEATURE_PACKAGES_x11-base = "packagegroup-core-x11-base"
|
|
FEATURE_PACKAGES_x11-sato = "packagegroup-core-x11-sato"
|
|
FEATURE_PACKAGES_tools-debug = "packagegroup-core-tools-debug"
|
|
FEATURE_PACKAGES_eclipse-debug = "packagegroup-core-eclipse-debug"
|
|
FEATURE_PACKAGES_tools-profile = "packagegroup-core-tools-profile"
|
|
FEATURE_PACKAGES_tools-testapps = "packagegroup-core-tools-testapps"
|
|
FEATURE_PACKAGES_tools-sdk = "packagegroup-core-sdk packagegroup-core-standalone-sdk-target"
|
|
FEATURE_PACKAGES_nfs-server = "packagegroup-core-nfs-server"
|
|
FEATURE_PACKAGES_nfs-client = "packagegroup-core-nfs-client"
|
|
FEATURE_PACKAGES_ssh-server-dropbear = "packagegroup-core-ssh-dropbear"
|
|
FEATURE_PACKAGES_ssh-server-openssh = "packagegroup-core-ssh-openssh"
|
|
FEATURE_PACKAGES_hwcodecs = "${MACHINE_HWCODECS}"
|
|
|
|
|
|
# IMAGE_FEATURES_REPLACES_foo = 'bar1 bar2'
|
|
# Including image feature foo would replace the image features bar1 and bar2
|
|
IMAGE_FEATURES_REPLACES_ssh-server-openssh = "ssh-server-dropbear"
|
|
# Do not install openssh complementary packages if either packagegroup-core-ssh-dropbear or dropbear
|
|
# is installed # to avoid openssh-dropbear conflict
|
|
# see [Yocto #14858] for more information
|
|
PACKAGE_EXCLUDE_COMPLEMENTARY:append = "${@bb.utils.contains_any('PACKAGE_INSTALL', 'packagegroup-core-ssh-dropbear dropbear', 'openssh', '' , d)}"
|
|
|
|
# IMAGE_FEATURES_CONFLICTS_foo = 'bar1 bar2'
|
|
# An error exception would be raised if both image features foo and bar1(or bar2) are included
|
|
|
|
MACHINE_HWCODECS ??= ""
|
|
|
|
CORE_IMAGE_BASE_INSTALL = '\
|
|
packagegroup-core-boot \
|
|
packagegroup-base-extended \
|
|
\
|
|
${CORE_IMAGE_EXTRA_INSTALL} \
|
|
'
|
|
|
|
CORE_IMAGE_EXTRA_INSTALL ?= ""
|
|
|
|
IMAGE_INSTALL ?= "${CORE_IMAGE_BASE_INSTALL}"
|
|
|
|
inherit image
|