mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 15:32:12 +02:00
c82f38999b
Fixup commit for prevous CVE-2022-33068 fix. Fixes: | In file included from ../harfbuzz-4.0.1/src/hb-ot-face.cc:39: 4429| ../harfbuzz-4.0.1/src/hb-ot-color-sbix-table.hh:301:11: error: use of bitwise '|' with boolean operands [-Werror,-Wbitwise-instead-of-logical] 4430| if (png.IHDR.height >= 65536 | png.IHDR.width >= 65536) 4431| ^~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 4432| || 4433| ../harfbuzz-4.0.1/src/hb-ot-color-sbix-table.hh:301:11: note: cast one or both operands to int to silence this warning 4434| 1 error generated. (From OE-Core rev: 7505ac6da37ba00d4dad74a0312ca20fc17e64df) Signed-off-by: Pavel Zhukov <pavel.zhukov@huawei.com> Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
2.0 KiB
BlitzBasic
51 lines
2.0 KiB
BlitzBasic
SUMMARY = "Text shaping library"
|
|
DESCRIPTION = "HarfBuzz is an OpenType text shaping engine."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/HarfBuzz"
|
|
BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=HarfBuzz"
|
|
SECTION = "libs"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6ee0f16281694fb6aa689cca1e0fb3da \
|
|
file://src/hb-ucd.cc;beginline=1;endline=15;md5=29d4dcb6410429195df67efe3382d8bc \
|
|
"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/${BPN}/${BPN}/releases"
|
|
UPSTREAM_CHECK_REGEX = "harfbuzz-(?P<pver>\d+(\.\d+)+).tar"
|
|
|
|
SRC_URI = "https://github.com/${BPN}/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.xz \
|
|
file://CVE-2022-33068.patch \
|
|
file://0001-Fix-conditional.patch"
|
|
SRC_URI[sha256sum] = "98f68777272db6cd7a3d5152bac75083cd52a26176d87bc04c8b3929d33bce49"
|
|
|
|
inherit meson pkgconfig lib_package gtk-doc gobject-introspection
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
GTKDOC_MESON_ENABLE_FLAG = 'enabled'
|
|
GTKDOC_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
PACKAGECONFIG ??= "cairo freetype glib icu"
|
|
PACKAGECONFIG[cairo] = "-Dcairo=enabled,-Dcairo=disabled,cairo"
|
|
PACKAGECONFIG[freetype] = "-Dfreetype=enabled,-Dfreetype=disabled,freetype"
|
|
PACKAGECONFIG[glib] = "-Dglib=enabled,-Dglib=disabled,glib-2.0"
|
|
PACKAGECONFIG[graphite] = "-Dgraphite=enabled,-Dgraphite=disabled,graphite2"
|
|
PACKAGECONFIG[icu] = "-Dicu=enabled,-Dicu=disabled,icu"
|
|
|
|
PACKAGES =+ "${PN}-icu ${PN}-icu-dev ${PN}-subset"
|
|
|
|
LEAD_SONAME = "libharfbuzz.so"
|
|
|
|
do_install:append() {
|
|
# If no tools are installed due to PACKAGECONFIG then this directory is
|
|
#still installed, so remove it to stop packaging wanings.
|
|
rmdir --ignore-fail-on-non-empty ${D}${bindir}
|
|
}
|
|
|
|
FILES:${PN}-icu = "${libdir}/libharfbuzz-icu.so.*"
|
|
FILES:${PN}-icu-dev = "${libdir}/libharfbuzz-icu.la \
|
|
${libdir}/libharfbuzz-icu.so \
|
|
${libdir}/pkgconfig/harfbuzz-icu.pc \
|
|
"
|
|
FILES:${PN}-subset = "${libdir}/libharfbuzz-subset.so.*"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|