mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
a487a51690
No upstream release notes. Upstream commits since 50.3.2: b6bbe236 Bump version: 50.3.2 → 51.0.0 7f477c52 Merge pull request #2472 from pypa/bugfix/2471-remove-deps 2a0463cb Update changelog. 99bc2c11 Remove tests guaranteeing that (vendored) dependencies can be installed without setuptools. 65441834 Remove conditional skip, no longer relevant. 9365c7ed Merge pull request #2468 from wimglenn/patch-1 43b0b81e Merge pull request #2461 from webknjaz/testing/gha-fix-set-env-usage 43f76003 Merge pull request #2460 from HaraldKorneliussen/master 2065f85d Merge pull request #2444 from zegor/patch-1 e9617599 Merge pull request #2439 from mgedmin/patch-1 475fb309 Update docs/pkg_resources.rst b4de397a fix broken link to entry-points details 4a4d50af Fix all deprecated set-env and add-path uses @ GHA b20d12e1 Fixes syntax issues in quickstart (#2448) 5cf3865f Merge pull request #2457 from webknjaz/testing/gha-broken-setup-python de48cfdb Temporarily allow `set-env` GHA commands ec944a40 Upgrade GHA actions using deprecated env mechanism d7170a28 Update quickstart.rst 0e1fc1c6 s/517/PEP 517/ 544687c3 Merge pull request #2437 from pypa/feature/rtd-2 3ca9e461 Merge pull request #2436 from webknjaz/maintenance/changelog-reconstruction 8ad16115 Merge pull request #2435 from pypa/debt/drop-py35 6597dcb6 Switch to RTD v2 config 7cf674e1 Reconstruct changelog with categories from history 97ee6624 Remove Python 3.5 from Appveyor tests 3dd7313d Bump PPC runs d490709b Merge pull request #2431 from webknjaz/bugfixes/pr-template-docs-links 66ca4205 Use 'virtualenv.python'. Fixes #2434. 419087c4 Merge branch 'master' into debt/drop-py35 38de858e Update changelog 6d33d5dd 📝 Update devguide links in the PR template 898ae046 Merge pull request #2430 from webknjaz/bugfixes/sphinx-failures a94c2c3d 📝 Add change notes e711cb07 🐛📝 Fix "Title level inconsistent" in changelog 9ab7bc54 Clean up syntax on entry_points.console_scripts. Fixes #2429. 2ff24f67 🐛📝 Fix the TOC link to the relocated dev guide a5dbf964 Drop support for Python 3.5. (From OE-Core rev: cf266444feb60ee8206d20104fead5d1b2f2cc16) Signed-off-by: Tim Orling <timothy.t.orling@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
66 lines
2.0 KiB
BlitzBasic
66 lines
2.0 KiB
BlitzBasic
SUMMARY = "Download, build, install, upgrade, and uninstall Python packages"
|
|
HOMEPAGE = "https://pypi.org/project/setuptools"
|
|
SECTION = "devel/python"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;beginline=1;endline=19;md5=9a33897f1bca1160d7aad3835152e158"
|
|
|
|
PYPI_PACKAGE_EXT = "zip"
|
|
|
|
inherit pypi setuptools3
|
|
|
|
SRC_URI_append_class-native = " file://0001-conditionally-do-not-fetch-code-by-easy_install.patch"
|
|
|
|
SRC_URI += "file://0001-change-shebang-to-python3.patch"
|
|
|
|
SRC_URI[sha256sum] = "029c49fd713e9230f6a41c0298e6e1f5839f2cde7104c0ad5e053a37777e7688"
|
|
|
|
DEPENDS += "${PYTHON_PN}"
|
|
|
|
RDEPENDS_${PN} = "\
|
|
${PYTHON_PN}-2to3 \
|
|
${PYTHON_PN}-compile \
|
|
${PYTHON_PN}-compression \
|
|
${PYTHON_PN}-ctypes \
|
|
${PYTHON_PN}-distutils \
|
|
${PYTHON_PN}-email \
|
|
${PYTHON_PN}-html \
|
|
${PYTHON_PN}-json \
|
|
${PYTHON_PN}-netserver \
|
|
${PYTHON_PN}-numbers \
|
|
${PYTHON_PN}-pickle \
|
|
${PYTHON_PN}-pkgutil \
|
|
${PYTHON_PN}-plistlib \
|
|
${PYTHON_PN}-shell \
|
|
${PYTHON_PN}-stringold \
|
|
${PYTHON_PN}-threading \
|
|
${PYTHON_PN}-unittest \
|
|
${PYTHON_PN}-xml \
|
|
"
|
|
|
|
do_install_prepend() {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
}
|
|
|
|
do_install_append() {
|
|
mv ${D}${bindir}/easy_install ${D}${bindir}/easy3_install
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# The pkg-resources module can be used by itself, without the package downloader
|
|
# and easy_install. Ship it in a separate package so that it can be used by
|
|
# minimal distributions.
|
|
PACKAGES =+ "${PYTHON_PN}-pkg-resources "
|
|
FILES_${PYTHON_PN}-pkg-resources = "${PYTHON_SITEPACKAGES_DIR}/pkg_resources/*"
|
|
RDEPENDS_${PYTHON_PN}-pkg-resources = "\
|
|
${PYTHON_PN}-compression \
|
|
${PYTHON_PN}-email \
|
|
${PYTHON_PN}-plistlib \
|
|
${PYTHON_PN}-pprint \
|
|
"
|
|
# Due to the way OE-Core implemented native recipes, the native class cannot
|
|
# have a dependency on something that is not a recipe name. Work around that by
|
|
# manually setting RPROVIDES.
|
|
RDEPENDS_${PN}_append = " ${PYTHON_PN}-pkg-resources"
|
|
RPROVIDES_append_class-native = " ${PYTHON_PN}-pkg-resources-native"
|