mirror of
https://git.yoctoproject.org/poky
synced 2026-03-05 23:09:39 +01:00
29d6678fd5
Having one monolithic packages directory makes it hard to find things and is generally overwhelming. This commit splits it into several logical sections roughly based on function, recipes.txt gives more information about the classifications used. The opportunity is also used to switch from "packages" to "recipes" as used in OpenEmbedded as the term "packages" can be confusing to people and has many different meanings. Not all recipes have been classified yet, this is just a first pass at separating things out. Some packages are moved to meta-extras as they're no longer actively used or maintained. Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
60 lines
1.4 KiB
PHP
60 lines
1.4 KiB
PHP
require gcc-configure-common.inc
|
|
|
|
EXTRA_OECONF_PATHS = " \
|
|
--with-local-prefix=${STAGING_DIR_TARGET}${prefix} \
|
|
--with-gxx-include-dir=${includedir}/c++/ \
|
|
--with-sysroot=${STAGING_DIR_TARGET} \
|
|
--with-build-sysroot=${STAGING_DIR_TARGET}"
|
|
|
|
RUNTIMETARGET = "libssp libstdc++-v3"
|
|
# ?
|
|
# libiberty
|
|
# libmudflap
|
|
# libgfortran
|
|
|
|
do_configure () {
|
|
export CXX="${CXX} -nostdinc++ -nostdlib++"
|
|
for d in ${RUNTIMETARGET}; do
|
|
echo "Configuring $d"
|
|
mkdir -p ${B}/$d/
|
|
cd ${B}/$d/
|
|
chmod a+x ${S}/$d/configure
|
|
${S}/$d/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
|
done
|
|
}
|
|
|
|
do_compile () {
|
|
for d in ${RUNTIMETARGET}; do
|
|
cd ${B}/$d/
|
|
oe_runmake
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
target=`echo ${MULTIMACH_TARGET_SYS} | sed -e s#-nativesdk##`
|
|
|
|
# Install libgcc from our gcc-cross saved data
|
|
install -d ${D}${base_libdir} ${D}${libdir}
|
|
cp -fpPR ${STAGING_INCDIR_NATIVE}/gcc-build-internal-$target/* ${D}
|
|
|
|
for d in ${RUNTIMETARGET}; do
|
|
cd ${B}/$d/
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
done
|
|
|
|
# Move libgcc_s into /lib
|
|
mkdir -p ${D}${base_libdir}
|
|
if [ -f ${D}${libdir}/nof/libgcc_s.so ]; then
|
|
mv ${D}${libdir}/nof/libgcc* ${D}${base_libdir}
|
|
else
|
|
mv ${D}${libdir}/libgcc* ${D}${base_libdir} || true
|
|
fi
|
|
}
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
|
|
PROVIDES = "virtual/${TARGET_PREFIX}compilerlibs"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|