mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 12:32:12 +02:00
f39676bf56
Version 3.7.2 includes a fix for CVE-2021-20305. (From OE-Core rev: 29f0ef2e32a9b55d8271fde240a4469070d57729) Signed-off-by: Trevor Gamblin <trevor.gamblin@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.2 KiB
BlitzBasic
58 lines
2.2 KiB
BlitzBasic
SUMMARY = "A low level cryptographic library"
|
|
DESCRIPTION = "Nettle is a cryptographic library that is designed to fit easily in more or less any context: In crypto toolkits for object-oriented languages (C++, Python, Pike, ...), in applications like LSH or GNUPG, or even in kernel space."
|
|
HOMEPAGE = "http://www.lysator.liu.se/~nisse/nettle/"
|
|
DESCRIPTION = "It tries to solve a problem of providing a common set of \
|
|
cryptographic algorithms for higher-level applications by implementing a \
|
|
context-independent set of cryptographic algorithms"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPLv3+ | GPLv2+"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING.LESSERv3;md5=6a6a8e020838b23406c81b19c1d46df6 \
|
|
file://COPYINGv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://serpent-decrypt.c;beginline=14;endline=36;md5=ca0d220bc413e1842ecc507690ce416e \
|
|
file://serpent-set-key.c;beginline=14;endline=36;md5=ca0d220bc413e1842ecc507690ce416e"
|
|
|
|
DEPENDS += "gmp"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/${BPN}/${BP}.tar.gz \
|
|
file://Add-target-to-only-build-tests-not-run-them.patch \
|
|
file://run-ptest \
|
|
file://check-header-files-of-openssl-only-if-enable_.patch \
|
|
"
|
|
|
|
SRC_URI_append_class-target = "\
|
|
file://dlopen-test.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "8d2a604ef1cde4cd5fb77e422531ea25ad064679ff0adf956e78b3352e0ef162"
|
|
|
|
UPSTREAM_CHECK_REGEX = "nettle-(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
inherit autotools ptest multilib_header
|
|
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
EXTRA_OECONF = "--disable-openssl"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest
|
|
}
|
|
|
|
do_install_append() {
|
|
oe_multilib_header nettle/version.h
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/testsuite/
|
|
install ${S}/testsuite/gold-bug.txt ${D}${PTEST_PATH}/testsuite/
|
|
install ${S}/testsuite/*-test ${D}${PTEST_PATH}/testsuite/
|
|
# tools can be found in PATH, not in ../tools/
|
|
sed -i -e 's|../tools/||' ${D}${PTEST_PATH}/testsuite/*-test
|
|
install ${B}/testsuite/*-test ${D}${PTEST_PATH}/testsuite/
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest += "${PN}-dev"
|
|
INSANE_SKIP_${PN}-ptest += "dev-deps"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|