mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
668a625ce5
Version 3.7.1 * Fix building packages which need execution to get the version number, and have a relative import in __init__.py (:ghpull:`531`). Version 3.7 * Support for :ref:`external data files <pyproject_toml_external_data>` such as man pages or Jupyter extension support files (:ghpull:`510`). * Project names are now lowercase in wheel filenames and .dist-info folder names, in line with the specifications (:ghpull:`498`). * Improved support for :doc:`bootstrapping <bootstrap>` a Python environment, e.g. for downstream packagers (:ghpull:`511`). flit_core.wheel is usable with python -m to create wheels before the build tool is available, and flit_core sdists also include a script to install itself from a wheel before installer is available. * Use newer importlib APIs, fixing some deprecation warnings (:ghpull:`499`). (From OE-Core rev: 3f6768cf23e4215d99f7279b8ec6ee73ba00a656) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.3 KiB
BlitzBasic
46 lines
1.3 KiB
BlitzBasic
SUMMARY = "This provides a PEP 517 build backend for packages using Flit."
|
|
DESCRIPTION = "This provides a PEP 517 build backend for packages using \
|
|
Flit. The only public interface is the API specified by PEP 517, at \
|
|
flit_core.buildapi."
|
|
HOMEPAGE = "https://github.com/pypa/flit"
|
|
BUGTRACKER = "https://github.com/pypa/flit/issues"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=41eb78fa8a872983a882c694a8305f08"
|
|
|
|
SRC_URI[sha256sum] = "3c9bd9c140515bfe62dd938c6610d10d6efb9e35cc647fc614fe5fb3a5036682"
|
|
|
|
inherit pip_install_wheel python3native python3-dir pypi setuptools3-base
|
|
|
|
DEPENDS:remove:class-native = " python3-pip-native"
|
|
DEPENDS:append:class-native = " unzip-native"
|
|
|
|
# We need the full flit tarball
|
|
PYPI_PACKAGE = "flit"
|
|
|
|
PIP_INSTALL_PACKAGE = "flit_core"
|
|
PIP_INSTALL_DIST_PATH = "${S}/flit_core/dist"
|
|
|
|
do_compile () {
|
|
nativepython3 flit_core/build_dists.py
|
|
}
|
|
|
|
do_install:class-native () {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
unzip -d ${D}${PYTHON_SITEPACKAGES_DIR} ./flit_core/dist/flit_core-${PV}-py3-none-any.whl
|
|
}
|
|
|
|
FILES:${PN} += "\
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core/* \
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core-${PV}.dist-info/* \
|
|
"
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES:${PN}-tests += "\
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core/tests/* \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|