mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 09:49:41 +01:00
4d4915a383
The libtelepathy-glib-dev package contains a .pc file that has a requires of pkgconfig(pkg-config) > 0.21 in it. In order to satisfy this requirement we add a manual RPROVIDE to the pkgconfig package. (From OE-Core rev: f9ddae16ef31b2c1cd988e1b416a39d516c986c4) Signed-off-by: Mark Hatle <mark.hatle@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.5 KiB
PHP
45 lines
1.5 KiB
PHP
SUMMARY = "Helper tool used when compiling"
|
|
DESCRIPTION = "pkg-config is a helper tool used when compiling applications and libraries. It helps determined \
|
|
the correct compiler/link options. It is also language-agnostic."
|
|
HOMEPAGE = "http://pkg-config.freedesktop.org/wiki/"
|
|
BUGTRACKER = "http://bugs.freedesktop.org/buglist.cgi?product=pkg-config"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = "glib-2.0 popt"
|
|
DEPENDS_class-native = ""
|
|
DEPENDS_class-nativesdk = ""
|
|
|
|
SRC_URI = "http://pkgconfig.freedesktop.org/releases/pkg-config-${PV}.tar.gz \
|
|
file://autofoo.patch \
|
|
file://glibconfig-sysdefs.h \
|
|
file://disable-legacy.patch"
|
|
|
|
S = "${WORKDIR}/pkg-config-${PV}/"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF = "--with-installed-glib --with-installed-popt --disable-legacy-scripts"
|
|
EXTRA_OECONF_class-native = "--disable-legacy-scripts"
|
|
EXTRA_OECONF_class-nativesdk = "--disable-legacy-scripts"
|
|
|
|
acpaths = "-I ."
|
|
do_configure_prepend () {
|
|
install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h glib-1.2.10/
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Set an empty dev package to ensure the base PN package gets
|
|
# the pkg.m4 macros, pkgconfig does not deliver any other -dev
|
|
# files.
|
|
FILES_${PN}-dev = ""
|
|
FILES_${PN} += "${datadir}/aclocal/pkg.m4"
|
|
|
|
# When using the RPM generated automatic package dependencies, some packages
|
|
# will end up requiring 'pkgconfig(pkg-config)'. Allow this behavior by
|
|
# specifying an appropriate provide.
|
|
RPROVIDES_${PN} += "pkgconfig(pkg-config) (= ${PV})"
|