mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
780033d5c4
Upstream has started using automake which means that the recipe must now inherit from autotools and pkgconfig. The source tree has been reorganised too which requires the paths in the patches to be modified. None of the patches appear to have been applied upstream. (From OE-Core rev: dacf6ab5aaf8cc588280b92d64db2e28c6c07a22) Signed-off-by: Mike Crowe <mac@mcrowe.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
2.0 KiB
BlitzBasic
49 lines
2.0 KiB
BlitzBasic
SUMMARY = "Tools for managing memory technology devices"
|
|
HOMEPAGE = "http://www.linux-mtd.infradead.org/"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
|
|
file://include/common.h;beginline=1;endline=17;md5=ba05b07912a44ea2bf81ce409380049c"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
DEPENDS = "zlib lzo e2fsprogs util-linux"
|
|
|
|
PV = "2.0.0"
|
|
|
|
SRCREV = "1bfee8660131fca7a18f68e9548a18ca6b3378a0"
|
|
SRC_URI = "git://git.infradead.org/mtd-utils.git \
|
|
file://add-exclusion-to-mkfs-jffs2-git-2.patch \
|
|
file://fix-armv7-neon-alignment.patch \
|
|
file://mtd-utils-fix-corrupt-cleanmarker-with-flash_erase--j-command.patch \
|
|
file://0001-Fix-build-with-musl.patch \
|
|
"
|
|
|
|
SRC_URI_append_libc-musl = " file://010-fix-rpmatch.patch "
|
|
|
|
S = "${WORKDIR}/git/"
|
|
|
|
# xattr support creates an additional compile-time dependency on acl because
|
|
# the sys/acl.h header is needed. libacl is not needed and thus enabling xattr
|
|
# regardless whether acl is enabled or disabled in the distro should be okay.
|
|
PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'xattr', 'xattr', '', d)}"
|
|
PACKAGECONFIG[xattr] = ",,acl,"
|
|
|
|
EXTRA_OEMAKE = "'CC=${CC}' 'RANLIB=${RANLIB}' 'AR=${AR}' 'CFLAGS=${CFLAGS} ${@bb.utils.contains('PACKAGECONFIG', 'xattr', '', '-DWITHOUT_XATTR', d)} -I${S}/include' 'BUILDDIR=${S}'"
|
|
|
|
do_install () {
|
|
oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} INCLUDEDIR=${includedir}
|
|
}
|
|
|
|
PACKAGES =+ "mtd-utils-jffs2 mtd-utils-ubifs mtd-utils-misc"
|
|
|
|
FILES_mtd-utils-jffs2 = "${sbindir}/mkfs.jffs2 ${sbindir}/jffs2dump ${sbindir}/jffs2reader ${sbindir}/sumtool"
|
|
FILES_mtd-utils-ubifs = "${sbindir}/mkfs.ubifs ${sbindir}/ubi*"
|
|
FILES_mtd-utils-misc = "${sbindir}/nftl* ${sbindir}/ftl* ${sbindir}/rfd* ${sbindir}/doc* ${sbindir}/serve_image ${sbindir}/recv_image"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# git/.compr.c.dep:46: warning: NUL character seen; rest of line ignored
|
|
# git/.compr.c.dep:47: *** missing separator. Stop.
|
|
PARALLEL_MAKE = ""
|