mirror of
https://git.yoctoproject.org/poky
synced 2026-03-31 20:02:22 +02:00
691a9908f5
Added two new flags to the configure script: --disable-Werror: don't treat all warnings all errors (which breaks compilation). PYTHON=/dev/null: this prevents distcc from detecting the host Python and trying to build its include server using the host Python. This disables the include server completely. If the include server is needed, that should be the object of another patch (and would introduce a dependency on python for distcc). The 'distcc-avahi' and 'makefile-param-order' patches are not needed anymore, as they were merged upstream. (From OE-Core rev: 3f33a6ecd9f1703381e175d688bdfce291ffdc8a) Signed-off-by: Bogdan Marinescu <bogdan.a.marinescu@intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
1.9 KiB
BlitzBasic
65 lines
1.9 KiB
BlitzBasic
SUMMARY = "A parallel build system"
|
|
DESCRIPTION = "distcc is a parallel build system that distributes \
|
|
compilation of C/C++/ObjC code across machines on a network."
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
PR = "r0"
|
|
|
|
DEPENDS = "avahi"
|
|
|
|
GTKCONFIG = "gtk"
|
|
GTKCONFIG_libc-uclibc = ""
|
|
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', '${GTKCONFIG}', '', d)}"
|
|
PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk --without-gnome,gtk+"
|
|
|
|
RRECOMMENDS_${PN} = "avahi-daemon"
|
|
|
|
SRC_URI = "http://distcc.googlecode.com/files/${BPN}-${PV}.tar.bz2 \
|
|
file://default \
|
|
file://distccmon-gnome.desktop \
|
|
file://distcc"
|
|
|
|
SRC_URI[md5sum] = "a1a9d3853df7133669fffec2a9aab9f3"
|
|
SRC_URI[sha256sum] = "f55dbafd76bed3ce57e1bbcdab1329227808890d90f4c724fcd2d53f934ddd89"
|
|
|
|
inherit autotools pkgconfig update-rc.d useradd
|
|
|
|
EXTRA_OECONF += "--disable-Werror PYTHON=/dev/null"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system \
|
|
--home /dev/null \
|
|
--no-create-home \
|
|
--gid nogroup \
|
|
distcc"
|
|
|
|
INITSCRIPT_NAME = "distcc"
|
|
|
|
do_install_append() {
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -d ${D}${sysconfdir}/default
|
|
install -m 0755 ${WORKDIR}/distcc ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/distcc
|
|
${DESKTOPINSTALL}
|
|
}
|
|
DESKTOPINSTALL = ""
|
|
DESKTOPINSTALL_libc-glibc () {
|
|
install -d ${D}${datadir}/distcc/
|
|
install -m 0644 ${WORKDIR}/distccmon-gnome.desktop ${D}${datadir}/distcc/
|
|
}
|
|
PACKAGES += "distcc-distmon-gnome"
|
|
|
|
FILES_${PN} = " ${sysconfdir} \
|
|
${bindir}/distcc \
|
|
${bindir}/lsdistcc \
|
|
${bindir}/distccd \
|
|
${bindir}/distccmon-text"
|
|
FILES_distcc-distmon-gnome = " ${bindir}/distccmon-gnome \
|
|
${datadir}/distcc"
|
|
|
|
pkg_postrm_${PN} () {
|
|
deluser distcc || true
|
|
}
|