mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
1f8c8aff09
A patch from 5.4 wasn't propagated to 5.8, and IKHEADERS was renabled in our default builds. This cases reproducibility issues when kernel modules are built. We haven't tracked down the root cause yet, but for now, we still don't want reproducibility failing on builds. There's a dedicated reproducibility feature available for those that want to enable the feature. (From OE-Core rev: ec23ada44fbf5143dd2cc89f3dd882be355358d0) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.9 KiB
BlitzBasic
45 lines
1.9 KiB
BlitzBasic
KBRANCH ?= "v5.8/standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
|
raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "6a095b50f83adc33b07bd1b3dbbcca8bec66849f"
|
|
SRCREV_meta ?= "0a4bef3856894e8bca3c74c97e7924ad262c0dc8"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.8;destsuffix=${KMETA}"
|
|
|
|
LINUX_VERSION ?= "5.8.4"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "2"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)"
|
|
|
|
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "" ,d)}"
|