mirror of
https://git.yoctoproject.org/poky
synced 2026-09-20 12:49:33 +02:00
860d4b1c86
NVD lists it as cryptography.io:cryptography and CNA lists it as pyca:cryptography, so set both vendor:product pairs to match correctly and precisely. Suggested-by: Ross Burton <ross.burton@arm.com> (From OE-Core rev: f4029c635ce3dc1470352d3d3381d9fef19426ed) Signed-off-by: mark.yang <mark.yang@lge.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b721019e0b2ccbaa8de267e14b282c48a5a3de8b) Signed-off-by: Himanshu Jadon <hjadon@cisco.com> Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev>
71 lines
2.0 KiB
BlitzBasic
71 lines
2.0 KiB
BlitzBasic
SUMMARY = "Provides cryptographic recipes and primitives to python developers"
|
|
HOMEPAGE = "https://cryptography.io/"
|
|
SECTION = "devel/python"
|
|
LICENSE = "Apache-2.0 | BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=8c3617db4fb6fae01f1d253ab91511e4 \
|
|
file://LICENSE.APACHE;md5=4e168cce331e5c827d4c2b68a6200e1b \
|
|
file://LICENSE.BSD;md5=5ae30ba4123bc4f2fa49aa0b0dce887b \
|
|
"
|
|
LDSHARED += "-pthread"
|
|
|
|
SRC_URI[sha256sum] = "6fe07eec95dfd477eb9530aef5bead34fec819b3aaf6c5bd6d20565da607bfe1"
|
|
|
|
SRC_URI += "file://0001-pyproject.toml-remove-benchmark-disable-option.patch \
|
|
file://CVE-2026-26007.patch \
|
|
file://check-memfree.py \
|
|
file://run-ptest \
|
|
"
|
|
|
|
require ${BPN}-crates.inc
|
|
|
|
inherit pypi python_setuptools3_rust cargo-update-recipe-crates pkgconfig
|
|
|
|
DEPENDS += " \
|
|
python3-cffi-native \
|
|
"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
python3-cffi \
|
|
"
|
|
|
|
RDEPENDS:${PN}:append:class-target = " \
|
|
python3-numbers \
|
|
python3-threading \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
python3-bcrypt \
|
|
python3-cryptography-vectors (= ${PV}) \
|
|
python3-hypothesis \
|
|
python3-iso8601 \
|
|
python3-mmap \
|
|
python3-pretend \
|
|
python3-psutil \
|
|
python3-pytest \
|
|
python3-unittest-automake-output \
|
|
python3-pytest-subtests \
|
|
python3-pytz \
|
|
"
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
install -D ${WORKDIR}/check-memfree.py ${D}${PTEST_PATH}/
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
|
|
# remove test_x509.py as it needs benchmark and we don't
|
|
# want to introduce the benchmark dependency
|
|
rm -rf ${D}${PTEST_PATH}/tests/bench/test_x509.py
|
|
install -d ${D}${PTEST_PATH}/tests/hazmat
|
|
cp -rf ${S}/tests/hazmat/* ${D}${PTEST_PATH}/tests/hazmat/
|
|
cp -r ${S}/pyproject.toml ${D}${PTEST_PATH}/
|
|
}
|
|
|
|
FILES:${PN}-dbg += " \
|
|
${PYTHON_SITEPACKAGES_DIR}/${SRCNAME}/hazmat/bindings/.debug \
|
|
"
|
|
|
|
CVE_PRODUCT = "cryptography.io:cryptography pyca:cryptography"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|