mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
bf669ec97f
Minor comment update and re-order variables to align more closely to the OE style-guide. (From OE-Core rev: 0b0c294ed3a9f901b9a6afaf984ff4958c327c0e) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
2.4 KiB
PHP
71 lines
2.4 KiB
PHP
SUMMARY = "Tool for working with series of patches"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/quilt/"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/quilt/quilt-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://Makefile \
|
|
file://test.sh \
|
|
file://0001-tests-Allow-different-output-from-mv.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c67ba0228f5b7b8bbe469474661f92d6"
|
|
SRC_URI[sha256sum] = "f6cbc788e5cbbb381a3c6eab5b9efce67c776a8662a7795c7432fd27aa096819"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
EXTRA_OECONF = "--with-perl='${USRBINPATH}/env perl' --with-patch=patch"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_BASH=/bin/bash"
|
|
|
|
# Make sure we don't have "-w" in shebang lines: it breaks using
|
|
# "/usr/bin/env perl" as parser
|
|
do_configure_prepend () {
|
|
find ${S} -name "*.in" -exec sed -i -e "1s,^#\!.*@PERL@ -w$,#\! @PERL@\nuse warnings;," {} \;
|
|
}
|
|
|
|
# Don't setup symlinks to host utilities, we don't need them
|
|
do_configure_append () {
|
|
sed -e 's,^COMPAT_SYMLINKS.*:=.*,COMPAT_SYMLINKS :=,' -i ${S}/Makefile
|
|
}
|
|
|
|
# quilt Makefiles install to BUILD_ROOT instead of DESTDIR
|
|
do_install () {
|
|
oe_runmake 'BUILD_ROOT=${D}' install
|
|
# cleanup unpackaged files
|
|
rm -rf ${D}/${datadir}/emacs
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake bin/patch-wrapper test/.depend
|
|
}
|
|
|
|
do_install_ptest() {
|
|
tar -c --exclude=\*.in bin/ | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -c --exclude=\*.in compat/ | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -c --exclude=\*.in quilt/ | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -c --exclude=mail.test --exclude=delete.test test/ | ( cd ${D}${PTEST_PATH} && tar -xf - && chmod 777 test)
|
|
cp ${WORKDIR}/Makefile ${D}${PTEST_PATH}
|
|
cp ${WORKDIR}/test.sh ${D}${PTEST_PATH}
|
|
}
|
|
|
|
PACKAGES += "guards guards-doc"
|
|
|
|
FILES_${PN} = "${sysconfdir} ${datadir}/quilt \
|
|
${bindir}/quilt ${libdir}/quilt"
|
|
FILES_guards = "${bindir}/guards"
|
|
FILES_${PN}-doc = "${mandir}/man1/quilt.1 ${docdir}/${BPN}"
|
|
FILES_guards-doc = "${mandir}/man1/guards.1"
|
|
|
|
RDEPENDS_${PN} = "bash"
|
|
RDEPENDS_${PN}-ptest = "make file sed gawk diffutils findutils ed perl \
|
|
perl-module-filehandle perl-module-getopt-std \
|
|
perl-module-posix perl-module-file-temp \
|
|
perl-module-text-parsewords perl-module-overloading \
|
|
bash util-linux-getopt \
|
|
"
|