mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 00:32:12 +02:00
e3af86e98d
Relicensed to just GPLv3+, update LICENSE and checksums. The build dependency for flex should be flex-native. libmath.h is missing from the tarball (it was present in 1.06) and the generation rules are not cross-friendly, so delete the rules and copy in a pre-generated libmath.h. Remove fix-segment-fault.patch as the fixes are now upstream. Add PACKAGECONFIG for readline and libedit, defaulting to readline. (From OE-Core rev: 9862849ba883c110e4d2c57c39ab2c58e9b2d216) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.2 KiB
BlitzBasic
33 lines
1.2 KiB
BlitzBasic
SUMMARY = "Arbitrary precision calculator language"
|
|
HOMEPAGE = "http://www.gnu.org/software/bc/bc.html"
|
|
|
|
LICENSE = "GPLv3+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://COPYING.LIB;md5=6a6a8e020838b23406c81b19c1d46df6 \
|
|
file://bc/bcdefs.h;endline=17;md5=4295c06df9e833519a342f7b5d43db06 \
|
|
file://dc/dc.h;endline=18;md5=36b8c600b63ee8c3aeade2764f6b2a4b \
|
|
file://lib/number.c;endline=20;md5=cf43068cc88f837731dc53240456cfaf"
|
|
|
|
SECTION = "base"
|
|
DEPENDS = "flex-native"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/${BPN}/${BP}.tar.gz \
|
|
file://no-gen-libmath.patch \
|
|
file://libmath.h"
|
|
SRC_URI[md5sum] = "cda93857418655ea43590736fc3ca9fc"
|
|
SRC_URI[sha256sum] = "62adfca89b0a1c0164c2cdca59ca210c1d44c3ffc46daf9931cf4942664cb02a"
|
|
|
|
inherit autotools texinfo update-alternatives
|
|
|
|
PACKAGECONFIG ??= "readline"
|
|
PACKAGECONFIG[readline] = "--with-readline,--without-readline,readline"
|
|
PACKAGECONFIG[libedit] = "--with-libedit,--without-libedit,libedit"
|
|
|
|
do_compile_prepend() {
|
|
cp -f ${WORKDIR}/libmath.h ${B}/bc/libmath.h
|
|
}
|
|
|
|
ALTERNATIVE_${PN} = "dc"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
BBCLASSEXTEND = "native" |