mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 15:32:13 +02:00
3fcd96ea1c
We are having the following error when using 'tar' from tar recipe to decompress .tar.bz2 files. tar (child): bzip2: Cannot exec: No such file or directory tar (child): Error is not recoverable: exiting now tar: Child returned status 2 tar: Error is not recoverable: exiting now The tar package is introduced by these two packagegroups into image. >From the README file from tar's source codes: """ ** gzip and bzip2. GNU tar uses the gzip and bzip2 programs to read and write compressed archives. If you don't have these programs already, you need to install them. """ So we'd better cluster gzip and bzip2 with tar. These two packagegroups already get 'gzip', so we also add 'bzip2'. (From OE-Core rev: ca69d793e4b987bd5202e1359ff82c515ad65a5a) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
142 lines
3.8 KiB
BlitzBasic
142 lines
3.8 KiB
BlitzBasic
#
|
|
# Copyright (C) 2010 Intel Corporation
|
|
#
|
|
|
|
SUMMARY = "Standard full-featured Linux system"
|
|
DESCRIPTION = "Package group bringing in packages needed for a more traditional full-featured Linux system"
|
|
PR = "r6"
|
|
|
|
inherit packagegroup
|
|
|
|
PACKAGES = "\
|
|
packagegroup-core-full-cmdline \
|
|
packagegroup-core-full-cmdline-libs \
|
|
packagegroup-core-full-cmdline-utils \
|
|
packagegroup-core-full-cmdline-extended \
|
|
packagegroup-core-full-cmdline-dev-utils \
|
|
packagegroup-core-full-cmdline-multiuser \
|
|
packagegroup-core-full-cmdline-initscripts \
|
|
packagegroup-core-full-cmdline-sys-services \
|
|
"
|
|
|
|
python __anonymous () {
|
|
# For backwards compatibility after rename
|
|
namemap = {}
|
|
namemap["packagegroup-core-full-cmdline"] = "packagegroup-core-basic"
|
|
namemap["packagegroup-core-full-cmdline-libs"] = "packagegroup-core-basic-libs"
|
|
namemap["packagegroup-core-full-cmdline-utils"] = "packagegroup-core-basic-utils"
|
|
namemap["packagegroup-core-full-cmdline-extended"] = "packagegroup-core-basic-extended"
|
|
namemap["packagegroup-core-full-cmdline-dev-utils"] = "packagegroup-core-dev-utils"
|
|
namemap["packagegroup-core-full-cmdline-multiuser"] = "packagegroup-core-multiuser"
|
|
namemap["packagegroup-core-full-cmdline-initscripts"] = "packagegroup-core-initscripts"
|
|
namemap["packagegroup-core-full-cmdline-sys-services"] = "packagegroup-core-sys-services"
|
|
|
|
packages = d.getVar("PACKAGES").split()
|
|
for pkg in packages:
|
|
if pkg.endswith('-dev'):
|
|
mapped = namemap.get(pkg[:-4], None)
|
|
if mapped:
|
|
mapped += '-dev'
|
|
elif pkg.endswith('-dbg'):
|
|
mapped = namemap.get(pkg[:-4], None)
|
|
if mapped:
|
|
mapped += '-dbg'
|
|
else:
|
|
mapped = namemap.get(pkg, None)
|
|
|
|
if mapped:
|
|
oldtaskname = mapped.replace("packagegroup-core", "task-core")
|
|
mapstr = " %s %s" % (mapped, oldtaskname)
|
|
d.appendVar("RPROVIDES_%s" % pkg, mapstr)
|
|
d.appendVar("RREPLACES_%s" % pkg, mapstr)
|
|
d.appendVar("RCONFLICTS_%s" % pkg, mapstr)
|
|
}
|
|
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline = "\
|
|
packagegroup-core-full-cmdline-libs \
|
|
packagegroup-core-full-cmdline-utils \
|
|
packagegroup-core-full-cmdline-extended \
|
|
packagegroup-core-full-cmdline-dev-utils \
|
|
packagegroup-core-full-cmdline-multiuser \
|
|
packagegroup-core-full-cmdline-initscripts \
|
|
packagegroup-core-full-cmdline-sys-services \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-libs = "\
|
|
glib-2.0 \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-utils = "\
|
|
bash \
|
|
acl \
|
|
attr \
|
|
bc \
|
|
coreutils \
|
|
cpio \
|
|
e2fsprogs \
|
|
ed \
|
|
file \
|
|
findutils \
|
|
gawk \
|
|
gmp \
|
|
grep \
|
|
makedevs \
|
|
mc \
|
|
mc-fish \
|
|
mc-helpers \
|
|
mc-helpers-perl \
|
|
ncurses \
|
|
net-tools \
|
|
procps \
|
|
psmisc \
|
|
sed \
|
|
tar \
|
|
time \
|
|
util-linux \
|
|
zlib \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-extended = "\
|
|
iproute2 \
|
|
iputils \
|
|
iptables \
|
|
module-init-tools \
|
|
openssl \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-dev-utils = "\
|
|
diffutils \
|
|
m4 \
|
|
make \
|
|
patch \
|
|
"
|
|
|
|
VIRTUAL-RUNTIME_initscripts ?= "initscripts"
|
|
VIRTUAL-RUNTIME_init_manager ?= "sysvinit"
|
|
VIRTUAL-RUNTIME_login_manager ?= "busybox"
|
|
VIRTUAL-RUNTIME_syslog ?= "sysklogd"
|
|
RDEPENDS_packagegroup-core-full-cmdline-initscripts = "\
|
|
${VIRTUAL-RUNTIME_initscripts} \
|
|
${VIRTUAL-RUNTIME_init_manager} \
|
|
ethtool \
|
|
${VIRTUAL-RUNTIME_login_manager} \
|
|
${VIRTUAL-RUNTIME_syslog} \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-multiuser = "\
|
|
bzip2 \
|
|
cracklib \
|
|
gzip \
|
|
shadow \
|
|
sudo \
|
|
"
|
|
|
|
RDEPENDS_packagegroup-core-full-cmdline-sys-services = "\
|
|
at \
|
|
cronie \
|
|
logrotate \
|
|
nfs-utils \
|
|
rpcbind \
|
|
"
|