mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 06:32:12 +02:00
04d388174e
Ensure we have virtual/crypt even if building without PAM; fixes: sudo: error in /etc/sudo.conf, line 0 while loading plugin "sudoers_policy" sudo: unable to load /usr/libexec/sudo/sudoers.so: /usr/libexec/sudo/sudoers.so: undefined symbol: crypt sudo: fatal error, unable to load plugins (From OE-Core rev: f863713ae255bf5b6619c98ecd36aacbda352bbb) Signed-off-by: Alex Kiernan <alex.kiernan@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.7 KiB
BlitzBasic
41 lines
1.7 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "http://ftp.sudo.ws/sudo/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-Include-sys-types.h-for-id_t-definition.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[md5sum] = "ea444d747feb1decfebdffd0b38b0739"
|
|
SRC_URI[sha256sum] = "d863d29b6fc87bc784a3223350e2b28a2ff2c4738f0fb8f1c92bb38c3017e679"
|
|
|
|
DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
EXTRA_OECONF += " \
|
|
ac_cv_type_rsize_t=no \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
|
|
echo 'auth required pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
|
|
sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
|
|
fi
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the /run directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libexecdir}/${BPN}/lib*${SOLIBSDEV} ${libexecdir}/${BPN}/*.la \
|
|
${libexecdir}/lib*${SOLIBSDEV} ${libexecdir}/*.la"
|