mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 21:32:13 +02:00
14220bb99c
Currently, the upstream check gives incorrect results: $ devtool latest-version libusb1 ... INFO: Current version: 1.0.26 INFO: Latest version: 1.0.27 There is no 1.0.27 release yet, only 1.0.27-rc1. Anuj Mittal has submitted the fix in v2: https://lists.openembedded.org/g/openembedded-core/message/192683 but the original version was applied instead. Fix it by passing "$" to make an exact match on the version. With this change applied, devtool reports the correct latest version: INFO: Current version: 1.0.26 INFO: Latest version: 1.0.26 (From OE-Core rev: 81b97e4727592e4abbbab284b8d8161c1eda52b8) Signed-off-by: Fabio Estevam <festevam@denx.de> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.4 KiB
BlitzBasic
50 lines
1.4 KiB
BlitzBasic
SUMMARY = "Userspace library to access USB (version 1.0)"
|
|
DESCRIPTION = "A cross-platform library to access USB devices from Linux, \
|
|
macOS, Windows, OpenBSD/NetBSD, Haiku and Solaris userspace."
|
|
HOMEPAGE = "https://libusb.info"
|
|
BUGTRACKER = "http://www.libusb.org/report"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/libusb-${PV}.tar.bz2 \
|
|
file://0001-configure.ac-Link-with-latomic-only-if-no-atomic-bui.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/libusb/libusb/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
|
|
|
|
SRC_URI[sha256sum] = "12ce7a61fc9854d1d2a1ffe095f7b5fac19ddba095c259e6067a46500381b5a5"
|
|
|
|
S = "${WORKDIR}/libusb-${PV}"
|
|
|
|
inherit autotools pkgconfig ptest github-releases
|
|
|
|
PACKAGECONFIG:class-target ??= "udev"
|
|
PACKAGECONFIG[udev] = "--enable-udev,--disable-udev,udev"
|
|
|
|
EXTRA_OECONF = "--libdir=${base_libdir}"
|
|
|
|
do_install:append() {
|
|
install -d ${D}${libdir}
|
|
if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
|
|
mv ${D}${base_libdir}/pkgconfig ${D}${libdir}
|
|
fi
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests stress
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -m 755 ${B}/tests/.libs/stress ${D}${PTEST_PATH}
|
|
}
|
|
|
|
FILES:${PN} += "${base_libdir}/*.so.*"
|
|
|
|
FILES:${PN}-dev += "${base_libdir}/*.so ${base_libdir}/*.la"
|