mirror of
https://git.yoctoproject.org/poky
synced 2026-07-04 14:13:38 +02:00
640927625e
Create the bbappend for v6.6 and bump the default kernel to v6.6 for all the machines. In the v6.6 kernel the dtb files for beaglebone have been moved to a vendor specific directory, so we also need to adjust the corresponding variables for its DTB generation. (From meta-yocto rev: 58ac51b7a44fbb165311c7226ae8b15cd004114d) Signed-off-by: Kevin Hao <kexin.hao@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
2.1 KiB
Plaintext
55 lines
2.1 KiB
Plaintext
#@TYPE: Machine
|
|
#@NAME: Beaglebone-yocto machine
|
|
#@DESCRIPTION: Reference machine configuration for http://beagleboard.org/bone and http://beagleboard.org/black boards
|
|
|
|
PREFERRED_PROVIDER_virtual/xserver ?= "xserver-xorg"
|
|
|
|
MACHINE_EXTRA_RRECOMMENDS = "kernel-modules"
|
|
|
|
EXTRA_IMAGEDEPENDS += "virtual/bootloader"
|
|
|
|
DEFAULTTUNE ?= "cortexa8hf-neon"
|
|
include conf/machine/include/arm/armv7a/tune-cortexa8.inc
|
|
|
|
IMAGE_FSTYPES += "tar.bz2 jffs2 wic wic.bmap"
|
|
EXTRA_IMAGECMD:jffs2 = "-lnp "
|
|
WKS_FILE ?= "beaglebone-yocto.wks"
|
|
MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "kernel-image kernel-devicetree"
|
|
do_image_wic[depends] += "mtools-native:do_populate_sysroot dosfstools-native:do_populate_sysroot virtual/bootloader:do_deploy"
|
|
|
|
SERIAL_CONSOLES ?= "115200;ttyS0 115200;ttyO0 115200;ttyAMA0"
|
|
|
|
PREFERRED_PROVIDER_virtual/kernel ?= "linux-yocto"
|
|
PREFERRED_VERSION_linux-yocto ?= "6.6%"
|
|
|
|
KERNEL_IMAGETYPE = "zImage"
|
|
DTB_FILES = "am335x-bone.dtb am335x-boneblack.dtb am335x-bonegreen.dtb"
|
|
KERNEL_DEVICETREE = '${@' '.join('ti/omap/%s' % d for d in '${DTB_FILES}'.split())}'
|
|
|
|
PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot"
|
|
|
|
SPL_BINARY = "MLO"
|
|
UBOOT_SUFFIX = "img"
|
|
UBOOT_MACHINE = "am335x_evm_defconfig"
|
|
|
|
MACHINE_FEATURES = "usbgadget usbhost vfat alsa"
|
|
|
|
IMAGE_BOOT_FILES ?= "u-boot.${UBOOT_SUFFIX} ${SPL_BINARY} ${KERNEL_IMAGETYPE} ${DTB_FILES}"
|
|
|
|
# support runqemu
|
|
EXTRA_IMAGEDEPENDS += "qemu-native qemu-helper-native"
|
|
IMAGE_CLASSES += "qemuboot"
|
|
QB_DEFAULT_FSTYPE = "wic"
|
|
QB_FSINFO = "wic:no-kernel-in-fs"
|
|
QB_KERNEL_ROOT = "/dev/vda2"
|
|
QB_SYSTEM_NAME = "qemu-system-arm"
|
|
QB_MACHINE = "-machine virt"
|
|
QB_CPU = "-cpu cortex-a15"
|
|
QB_KERNEL_CMDLINE_APPEND = "console=ttyAMA0 systemd.mask=systemd-networkd"
|
|
QB_OPT_APPEND = "-device virtio-rng-device"
|
|
QB_TAP_OPT = "-netdev tap,id=net0,ifname=@TAP@,script=no,downscript=no"
|
|
QB_NETWORK_DEVICE = "-device virtio-net-device,netdev=net0,mac=@MAC@"
|
|
QB_ROOTFS_OPT = "-drive id=disk0,file=@ROOTFS@,if=none,format=raw -device virtio-blk-device,drive=disk0"
|
|
QB_SERIAL_OPT = ""
|
|
QB_TCPSERIAL_OPT = "-device virtio-serial-device -chardev socket,id=virtcon,port=@PORT@,host=127.0.0.1 -device virtconsole,chardev=virtcon"
|