mirror of
https://git.yoctoproject.org/poky
synced 2026-06-21 22:53:48 +02:00
3acfc1acbd
Fixes [YOCTO #16265] The glibc recipe is supposed to be building with --enable-stack-protector=strong, but some CACHED_CONFIGVARS values are actually breaking this, causing glibc to be built with no stack protector at all. Remove these CACHED_CONFIGVARS values so that stack protector support is detected properly in do_configure and then enabled properly during do_compile. Full details are here: https://bugzilla.yoctoproject.org/show_bug.cgi?id=16265 (From OE-Core rev: 7952d214393b6c5230ba115f63b6f6d245a728bc) Signed-off-by: Ivan Nestlerode <ivan.nestlerode@sonos.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 43f0602ede37428f3c35cf665bba934b84355240) Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev>
54 lines
1.8 KiB
PHP
54 lines
1.8 KiB
PHP
require glibc-common.inc
|
|
require glibc-ld.inc
|
|
|
|
DEPENDS = "virtual/${HOST_PREFIX}gcc virtual/${HOST_PREFIX}binutils libgcc-initial linux-libc-headers"
|
|
|
|
PROVIDES = "virtual/libc"
|
|
PROVIDES += "virtual/libintl virtual/libiconv"
|
|
inherit autotools texinfo systemd
|
|
|
|
LEAD_SONAME = "libc.so"
|
|
|
|
# msgfmt could come from gettext-native but we don't depend on that and
|
|
# disable for reproducibility
|
|
CACHED_CONFIGUREVARS += " \
|
|
ac_cv_path_BASH_SHELL=${base_bindir}/bash \
|
|
ac_cv_prog_MSGFMT= \
|
|
libc_cv_slibdir=${base_libdir} \
|
|
libc_cv_rootsbindir=${base_sbindir} \
|
|
libc_cv_localedir=${localedir} \
|
|
libc_cv_include_x86_isa_level=no \
|
|
"
|
|
|
|
# ifunc doesn't appear to work on mips, casuses libbfd assertion failures
|
|
CACHED_CONFIGUREVARS:append:mipsarch = " libc_cv_ld_gnu_indirect_function=no"
|
|
|
|
GLIBC_EXTRA_OECONF ?= ""
|
|
GLIBC_EXTRA_OECONF:class-nativesdk = ""
|
|
|
|
# glibc uses PARALLELMFLAGS variable to pass parallel build info so transfer
|
|
# PARALLEL_MAKE into PARALLELMFLAGS and empty out PARALLEL_MAKE
|
|
EGLIBCPARALLELISM := "PARALLELMFLAGS="${PARALLEL_MAKE}""
|
|
EXTRA_OEMAKE[vardepsexclude] += "EGLIBCPARALLELISM"
|
|
EXTRA_OEMAKE += "${EGLIBCPARALLELISM}"
|
|
PARALLEL_MAKE = ""
|
|
|
|
# glibc make-syscalls.sh has a number of issues with /bin/dash and
|
|
# it's output which make calls via the SHELL also has issues, so
|
|
# ensure make uses /bin/bash
|
|
EXTRA_OEMAKE += "SHELL=/bin/bash"
|
|
|
|
# We do not need bash to run tzselect script, the default is to use
|
|
# bash but it can be configured by setting KSHELL Makefile variable
|
|
EXTRA_OEMAKE += "KSHELL=/bin/sh"
|
|
|
|
do_configure:prepend() {
|
|
sed -e "s#/bin/bash#/bin/sh#" -i ${S}/elf/ldd.bash.in
|
|
}
|
|
|
|
# Enable backtrace from abort()
|
|
do_configure:append:arm () {
|
|
echo "CFLAGS-abort.c = -fasynchronous-unwind-tables" >> ${B}/configparms
|
|
echo "CFLAGS-raise.c = -fasynchronous-unwind-tables" >> ${B}/configparms
|
|
}
|