mirror of
https://git.yoctoproject.org/poky
synced 2026-06-21 13:54:22 +02:00
2775596cb2
This includes fix for: CVE-2024-4693, CVE-2024-6505 and CVE-2024-7730 General changelog for 8.2: https://wiki.qemu.org/ChangeLog/8.2 Droped: 0001-target-riscv-kvm-change-KVM_REG_RISCV_FP_F-to-u32.patch 0002-target-riscv-kvm-change-KVM_REG_RISCV_FP_D-to-u64.patch 0003-target-riscv-kvm-change-timer-regs-size-to-u64.patch CVE-2024-4467 and CVE-2024-7409 since already contained the fix. (From OE-Core rev: 7983ad282c37f8c1125da5bab96489e5d0039948) Signed-off-by: Yogita Urade <yogita.urade@windriver.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
32 lines
1.1 KiB
BlitzBasic
32 lines
1.1 KiB
BlitzBasic
BPN = "qemu"
|
|
|
|
require qemu-native.inc
|
|
|
|
# As some of the files installed by qemu-native and qemu-system-native
|
|
# are the same, we depend on qemu-native to get the full installation set
|
|
# and avoid file clashes
|
|
DEPENDS += "glib-2.0-native zlib-native pixman-native qemu-native"
|
|
|
|
EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
|
|
|
|
PACKAGECONFIG ??= "fdt alsa kvm pie slirp png \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
|
|
"
|
|
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
|
|
|
|
do_install:append() {
|
|
install -Dm 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
|
|
# The following is also installed by qemu-native
|
|
rm -f ${D}${datadir}/qemu/trace-events-all
|
|
rm -rf ${D}${datadir}/qemu/keymaps
|
|
rm -rf ${D}${datadir}/icons/
|
|
rm -rf ${D}${includedir}/qemu-plugin.h
|
|
|
|
# Install qmp.py to be used with testimage
|
|
install -d ${D}${libdir}/qemu-python/qmp/
|
|
install -D ${S}/python/qemu/qmp/* ${D}${libdir}/qemu-python/qmp/
|
|
}
|