mirror of
https://git.yoctoproject.org/poky
synced 2026-06-21 13:54:22 +02:00
35bd8118fc
When building libinput with the 'gui' PACKAGECONFIG option, it fails with: | Run-time dependency x11 found: YES 1.8.9 | Run-time dependency wayland-client found: YES 1.22.0 | Run-time dependency wayland-protocols found: YES 1.34 | Program wayland-scanner found: NO | | ../git/meson.build:578:20: ERROR: Program 'wayland-scanner' not found or not executable | | A full log can be found at /home/marc/mnt/yocto-latest/build/tmp/work/core2-64-poky-linux/libinput/1.25.0/build/meson-logs/meson-log.txt | ERROR: meson failed | WARNING: exit code 1 from a shell command. Adding a build dependency on wayland-native fixes the issue. (From OE-Core rev: 71e49dcac0be026d12140598850e2cd38d702317) Signed-off-by: Marc Ferland <marc.ferland@sonatest.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 0e2d18e6267d26870ccbe45734bfccbc02744357) Signed-off-by: Steve Sakoman <steve@sakoman.com>
50 lines
1.9 KiB
BlitzBasic
50 lines
1.9 KiB
BlitzBasic
SUMMARY = "Library to handle input devices in Wayland compositors"
|
|
DESCRIPTION = "libinput is a library to handle input devices in Wayland \
|
|
compositors and to provide a generic X.Org input driver. It provides \
|
|
device detection, device handling, input device event processing and \
|
|
abstraction so minimize the amount of custom input code compositors need to \
|
|
provide the common set of functionality that users expect."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/libinput/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=bab4ac7dc1c10bc0fb037dc76c46ef8a"
|
|
|
|
DEPENDS = "libevdev udev mtdev"
|
|
|
|
SRC_URI = "git://gitlab.freedesktop.org/libinput/libinput.git;protocol=https;branch=main \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "3fd38d89276b679ac3565efd7c2150fd047902cb"
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_REGEX = "libinput-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
|
|
|
|
inherit meson pkgconfig lib_package ptest
|
|
|
|
# Patch out build directory, otherwise it leaks into ptest binary
|
|
do_configure:append() {
|
|
sed -i -e "s,${WORKDIR},,g" config.h
|
|
if [ -e "litest-config.h" ]; then
|
|
sed -i -e "s,${WORKDIR},,g" litest-config.h
|
|
fi
|
|
}
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true,-Dlibwacom=false,libwacom"
|
|
PACKAGECONFIG[gui] = "-Ddebug-gui=true,-Ddebug-gui=false,cairo gtk+3 wayland-native"
|
|
PACKAGECONFIG[tests] = "-Dtests=true -Dinstall-tests=true,-Dtests=false -Dinstall-tests=false,libcheck"
|
|
|
|
UDEVDIR = "`pkg-config --variable=udevdir udev`"
|
|
|
|
EXTRA_OEMESON += "-Dudev-dir=${UDEVDIR} \
|
|
-Ddocumentation=false \
|
|
-Dzshcompletiondir=no"
|
|
|
|
# package name changed in 1.8.1 upgrade: make sure package upgrades work
|
|
RPROVIDES:${PN} = "libinput"
|
|
RREPLACES:${PN} = "libinput"
|
|
RCONFLICTS:${PN} = "libinput"
|
|
|
|
FILES:${PN}-ptest += "${libexecdir}/libinput/libinput-test-suite"
|