mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 21:32:12 +02:00
90e0a0f7f4
The idea of the base class dependency is to say "yes, I need a C cross compiler" and this was never meant to be gcc specific. Looking at the codebase, whilst we code triplets into this, it does overcomplicate things as there are only ever limited, "target", "sdk" and the class extended versions like mutlilib. After much thought, we can simplify this to virtual/cross-cc and virtual/nativesdk-cross-cc. This lets us remove the "gcc" specific element as well as removing the over complicated triplet usage. At the same time, change the much less widely used "g++" variant to "c++" for similar reasons and remove the triplet from virtual/XXX-binutils too. Backwards compatibility mappings could be left but are just going to confuse things in future so we'll just require users to update. This simplification, whilst disruptive for any toolchain focused layers, will make improved toolchain selection in the future much easier. Since we no longer have overlapping variables, some code for that can just be removed. The class extension code does need to start remapping some variables but not the crosssdk target recipe names. This patch is in two pieces, this one handles the renaming with the functional changes separate in a second for easier review even if this breaks bisection. (From OE-Core rev: 4ccc3bc8266c327bcc18c9a3faf7536210dfb9f0) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
90 lines
2.9 KiB
PHP
90 lines
2.9 KiB
PHP
require gcc-configure-common.inc
|
|
|
|
EXTRA_OECONF_PATHS = "\
|
|
--with-sysroot=/not/exist \
|
|
--with-build-sysroot=${STAGING_DIR_TARGET} \
|
|
"
|
|
|
|
# An arm hard float target like raspberrypi4 won't build
|
|
# as CFLAGS don't make it to the fortran compiler otherwise
|
|
# (the configure script sets FC to $GFORTRAN unconditionally)
|
|
export GFORTRAN = "${FC} -fcanon-prefix-map -fdebug-prefix-map=${S}=${TARGET_DBGSRC_DIR} -fdebug-prefix-map=${B}=${TARGET_DBGSRC_DIR} -gno-record-gcc-switches"
|
|
|
|
do_configure () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
rm -rf ${B}/${TARGET_SYS}/$target/
|
|
mkdir -p ${B}/${TARGET_SYS}/$target/
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
chmod a+x ${S}/$target/configure
|
|
relpath=${@os.path.relpath("${S}", "${B}/${TARGET_SYS}")}
|
|
../$relpath/$target/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
|
# Easiest way to stop bad RPATHs getting into the library since we have a
|
|
# broken libtool here
|
|
sed -i -e 's/hardcode_into_libs=yes/hardcode_into_libs=no/' ${B}/${TARGET_SYS}/$target/libtool
|
|
done
|
|
}
|
|
EXTRACONFFUNCS += "extract_stashed_builddir"
|
|
do_configure[depends] += "${COMPILERDEP}"
|
|
|
|
do_compile () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$target/
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
cd ${B}/${TARGET_SYS}/libgfortran/
|
|
oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/libgfortran/ install
|
|
if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
|
|
fi
|
|
if [ -d ${D}${infodir} ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
|
|
fi
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
# avoid virtual/libc
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "virtual/cross-cc virtual/compilerlibs"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
PACKAGES = "\
|
|
${PN}-dbg \
|
|
libgfortran \
|
|
libgfortran-dev \
|
|
libgfortran-staticdev \
|
|
"
|
|
|
|
LICENSE:${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
FILES:${PN} = "${libdir}/libgfortran.so.*"
|
|
FILES:${PN}-dev = "\
|
|
${libdir}/libgfortran*.so \
|
|
${libdir}/libgfortran.spec \
|
|
${libdir}/libgfortran.la \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libgfortranbegin.* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libcaf_single* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude/ \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/include/ \
|
|
"
|
|
FILES:${PN}-staticdev = "${libdir}/libgfortran.a"
|
|
|
|
INSANE_SKIP:${MLPREFIX}libgfortran-dev = "staticdev"
|
|
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
python __anonymous () {
|
|
f = d.getVar("FORTRAN")
|
|
if "fortran" not in f:
|
|
raise bb.parse.SkipRecipe("libgfortran needs fortran support to be enabled in the compiler")
|
|
}
|